在s/merge中总是失败的匿名谓词

Question

user=> (require '[clojure.spec.alpha :as s])
nil
user=> (s/def ::a int?)
:user/a
user=> (s/def ::b int?)
:user/b
user=> (s/def ::c (s/merge (s/keys :req [::a ::b]) #(< (::a %) (::b %))))
:user/c
user=> (s/explain-data ::c {::a 0 ::b 1})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 0, :b 1}, :via [:user/c], :in []}), :spec :user/c, :value #:user{:a 0, :b 1}}
user=> ;; ^^ 不符合预期
user=> (s/explain-data ::c {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/c], :in []}), :spec :user/c, :value #:user{:a 1, :b 0}}
user=> ;; ^^ 应符合预期
user=> (s/def ::a<b #(< (::a %) (::b %)))
:user/a<b
user=> (s/def ::d (s/merge (s/keys :req [::a ::b]) ::a<b))
:user/d
user=> (s/explain-data ::d {::a 0 ::b 1})
nil
user=> (s/explain-data ::d {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/d :user/a<b], :in []}), :spec :user/d, :value #:user{:a 1, :b 0}}

Answer 1

_评论者：dchelimsky_

当引用谓词函数时也会总是失败，所以使其工作唯一的正确方法就是定义另一个spec并引用它。


user=> (defn a<b [a b] (< a b))
#'user/a<b
user=> (s/def ::e (s/merge (s/keys :req [::a ::b]) a<b))
:user/e
user=> (s/explain-data ::e {::a 1 ::b 2})
#:clojure.spec.alpha{:problems ({:path [], :pred user/a<b, :val #:user{:a 1, :b 2}, :via [:user/e], :in []}), :spec :user/e, :value #:user{:a 1, :b 2}}
user=> (s/explain-data ::e {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred user/a<b, :val #:user{:a 1, :b 0}, :via [:user/e], :in []}), :spec :user/e, :value #:user{:a 1, :b 0}}

Answer 2

由 alexmiller 发表的评论：

(< (::a % ::b %)) 似乎不正确？#(< (::a %) (::b %)) 能行吗？

Answer 3

由 dchelimsky 发表的评论：

发现了一个好问题，然而，#(< (::a %) (::b %)) 并不能在行内工作。我已经更新了示例以反映这一点。

Answer 4

由 dchelimsky 发表的评论：

顺便说一句，我之前在其他地方缩小了问题范围，在此之前我犯了一个打字错误 :) 恰巧的是，无论是带打字错误还是不带，我都得到了相同的回答。

Answer 5

_评论者：dchelimsky_

如果你将谓词用 {s/spec} 括起来，它是可以工作的。


user=> (s/def ::f (s/merge (s/keys :req [::a ::b]) (s/spec #(< (::a %) (::b %)))))
:user/f
user=> (s/explain-data ::f {::a 1 ::b 2})
nil
user=> (s/explain-data ::f {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/f], :in []}), :spec :user/f, :value #:user{:a 1, :b 0}}

Answer 6

_评论来自：jcr_

我无法重现这些问题。

在问题描述中，谓词 {{#(< (::a %) (::b %))}} 需要a小于b，所以预期中 {{::a 1 ::b 0}} 不符合规范。

在第一条评论中，谓词 {{a<b}} 是无效的，因为它接受两个数字而不是一个单一映射。

以下片段也按预期工作（匿名谓词、命名谓词和用 s/spec 括起来的谓词之间没有区别）

(s/def ::a number?)
(defn good? [m] (contains? m :a))

(def s1 (s/merge (s/keys :req-un [::a]) good?))
(def s2 (s/merge (s/keys :req-un [::a]) #(contains? % :a)))
(def s3 (s/merge (s/keys :req-un [::a]) (s/spec #(contains? % :a))))

(s/valid? s1 {:a 42}) ;=> true
(s/valid? s2 {:a 42}) ;=> true
(s/valid? s3 {:a 42}) ;=> true


我相信这个问题可以关闭。

Answer 7

由 dchelimsky 发表的评论：

在我根据Alex的评论更新示例后，我把消息放在了错误的位置。我刚刚又更新了一次，使得消息与我输出的结果正确对齐。jcr，我确实看到你的示例是有效的，但我的例子仍然不行。所以这并不像所有匿名谓词那样具有普遍性，但仍然存在令人惊讶的行为。

话虽如此，s/merge文档说明它支持键规范，并未声明支持任何其他类型的谓词，因此如果您想根据这个理由关闭它，那就可以了。

Answer 8

_评论来自：jcr_

哦，现在我明白了你的意思。对不起，我之前下了定论。

所以这里实际的問題是，在使用不包裹在s/spec调用中的谓词时，当使用s/merge时，s/explain不一致地报告根据s/conform有效的输入。以下是我设法提出的最小示例


(ns test
  (:require [clojure.spec.alpha :as s]))

(defn pred [m] (contains? m :a))
(s/def ::s (s/merge pred))

(def good {:a 42})
(def bad  {})

;; 如预期
(s/conform ::s good) ;=> {:a 42}
(s/conform ::s bad)  ;=> :clojure.spec.alpha/invalid

;; !!!: 第一个不应该失败
(s/explain-str ::s good) ;=> "val: {:a 42} fails spec: :test/s predicate: pred\n"
(s/explain-str ::s bad)  ;=> "val: {} fails spec: :test/s predicate: pred\n"

;; 显式地包装pred到spec中
(s/def ::s* (s/merge (s/spec pred)))

;; 现在，按预期工作
(s/explain-str ::s* good) ;=> "Success!\n"
(s/explain-str ::s* bad)  ;=> "val: {} fails spec: :test/s* predicate: pred\n"


如果你不介意的话，我建议相应地更新标题和描述？

Answer 9

_评论来自：jcr_

据我所知，问题在于{{merge-spec-impl}}只是简单地调用{{explain-1}}，给出给定的谓词，并且{{explain-1}}总是在{{(spec? pred)}}为false时返回问题；merge-spec-impl可能应该在它的谓词上调用{{specize}}，类似于在{{tuple-impl}}中怎么做


(let [specs (delay (mapv specize preds forms)) ...] ...)

Answer 10

参考资料：https://clojure.atlassian.net/browse/CLJ-2321（由dchelimsky报告）