在s/merge中的匿名谓词总是失败

Question

user=> (require '[clojure.spec.alpha :as s])
nil
user=> (s/def ::a int?)
:user/a
user=> (s/def ::b int?)
:user/b
user=> (s/def ::c (s/merge (s/keys :req [::a ::b]) #(< (::a %) (::b %))))
:user/c
user=> (s/explain-data ::c {::a 0 ::b 1})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 0, :b 1}, :via [:user/c], :in []}), :spec :user/c, :value #:user{:a 0, :b 1}}
user=> ;; ^^ 不期望的结果
user=> (s/explain-data ::c {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/c], :in []}), :spec :user/c, :value #:user{:a 1, :b 0}}
user=> ;; ^^ 预期结果
user=> (s/def ::a<b #(< (::a %) (::b %)))
:user/a<b
user=> (s/def ::d (s/merge (s/keys :req [::a ::b]) ::a<b))
:user/d
user=> (s/explain-data ::d {::a 0 ::b 1})
nil
user=> (s/explain-data ::d {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/d :user/a<b], :in []}), :spec :user/d, :value #:user{:a 1, :b 0}}

Answer 1

_由：dchelimsky_ 发布的评论

当引用谓词函数时，它也总是失败，所以让它工作唯一的方法是定义另一个spec并引用它。


user=> (defn a<b [a b] (< a b))
#'user/a<b
user=> (s/def ::e (s/merge (s/keys :req [::a ::b]) a<b))
:user/e
user=> (s/explain-data ::e {::a 1 ::b 2})
#:clojure.spec.alpha{:problems ({:path [], :pred user/a<b, :val #:user{:a 1, :b 2}, :via [:user/e], :in []}), :spec :user/e, :value #:user{:a 1, :b 2}}
user=> (s/explain-data ::e {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred user/a<b, :val #:user{:a 1, :b 0}, :via [:user/e], :in []}), :spec :user/e, :value #:user{:a 1, :b 0}}

Answer 2

由 alexmiller 发表的评论：

(< (::a % ::b %)) 似乎不正确？#(< (::a %) (::b %)) 是否可以工作？

Answer 3

由 dchelimsky 发表的评论：

抓住了一个好机会，但是没有 #(< (::a %) (::b %)) 也不在行。我已经更新了示例来反映这一点。

Answer 4

由 dchelimsky 发表的评论：

此外，顺带一提，在打字错误之前，我已经在其他地方缩小了问题范围 :) 正巧，我无论是否有打字错误，都得到了同样的答案。

Answer 5

_由：dchelimsky_ 发布的评论

如果您在 {s/spec} 中包含谓词，则可以工作。


user=> (s/def ::f (s/merge (s/keys :req [::a ::b]) (s/spec #(< (::a %) (::b %)))))
:user/f
user=> (s/explain-data ::f {::a 1 ::b 2})
nil
user=> (s/explain-data ::f {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/f], :in []}), :spec :user/f, :value #:user{:a 1, :b 0}}

Answer 6

_由 jcr 发表的评论

我无法重现这个问题。

在问题描述中，谓词 {{#(< (::a %) (::b %))}} 需要a小于b，因此预期 {{::a 1 ::b 0}} 不符合规范。

在第一则评论中，谓词 {{a<b}} 无效，因为它接受两个数字，而不是一个单个的map。

以下片段也按预期工作（无匿名谓词、命名谓词或包含在s/spec中的谓词之间的区别）

(s/def ::a number?)
(defn good? [m] (contains? m :a))

(def s1 (s/merge (s/keys :req-un [::a]) good?))
(def s2 (s/merge (s/keys :req-un [::a]) #(contains? % :a)))
(def s3 (s/merge (s/keys :req-un [::a]) (s/spec #(contains? % :a))))

(s/valid? s1 {:a 42}) ;=> true
(s/valid? s2 {:a 42}) ;=> true
(s/valid? s3 {:a 42}) ;=> true


我相信这个问题可以关闭了。

Answer 7

由 dchelimsky 发表的评论：

在我根据 Alex 的评论更新示例后，我把消息放在了错误的位置。我刚刚又更新了一次，确保消息与输出正确对齐。jcr，我确实看到你的例子可以工作，但我的例子仍然不行。所以这并不像所有匿名谓词那样通用，但仍然存在令人惊讶的行为。

虽然如此，s/merge 文档说明它支持键规范，并未声明支持任何其他类型的谓词，所以如果你想基于这些理由将其关闭，那请随意吧。

Answer 8

_由 jcr 发表的评论

啊，现在我明白你的意思了。对不起，我跳到结论了。

所以这里实际的问题是，{{s/explain}}在使用未用{{s/spec}}调用的谓词与{{s/merge}}一起使用时，不一致地报告了根据{{s/conform}}有效的输入。以下是我设法编写的最小示例：


(ns test)
  (:require [clojure.spec.alpha :as s]))

(defn pred [m] (contains? m :a))
(s/def ::s (s/merge pred))

(def good {:a 42})
(def bad  {})

;; 如预期
(s/conform ::s good) ;=> {:a 42}
(s/conform ::s bad)  ;=> :clojure.spec.alpha/invalid

;; !!!: 第一个不应该失败
(s/explain-str ::s good) ;=> "val: {:a 42} fails spec: :test/s predicate: pred\n"
(s/explain-str ::s bad)  ;=> "val: {} fails spec: :test/s predicate: pred\n"

;; 明确包装 pred 在 spec 中
(s/def ::s* (s/merge (s/spec pred)))

;; 现在，如预期一样工作
(s/explain-str ::s* good) ;=> "Success!\n"
(s/explain-str ::s* bad)  ;=> "val: {} fails spec: :test/s* predicate: pred\n"


如果你不介意的话，我建议相应地更新标题和描述。

Answer 9

_由 jcr 发表的评论

据我所知，问题在于{{merge-spec-impl}}简单地调用{{explain-1}}并通过给定的谓词，{{explain-1}}如果{{(spec? pred)}}为假总返回问题；merge-spec-impl可能应该在其谓词上调用{{specize}}，类似于在{{tuple-impl}}中完成的方式。


(let [specs (delay (mapv specize preds forms)) ...] ...)

Answer 10

参考： https://clojure.atlassian.net/browse/CLJ-2321 (dchelimsky 报告)