在 s/merge 中的匿名谓词始终失败

Question

user=> (require '[clojure.spec.alpha :as s])
nil
user=> (s/def ::a int?)
:user/a
user=> (s/def ::b int?)
:user/b
user=> (s/def ::c (s/merge (s/keys :req [::a ::b]) #(< (::a %) (::b %))))
:user/c
user=> (s/explain-data ::c {::a 0 ::b 1})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 0, :b 1}, :via [:user/c], :in []}), :spec :user/c, :value #:user{:a 0, :b 1}}
user=> ;; ^^ 不符合预期
user=> (s/explain-data ::c {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/c], :in []}), :spec :user/c, :value #:user{:a 1, :b 0}}
user=> ;; ^^ 符合预期
user=> (s/def ::a<b #(< (::a %) (::b %)))
:user/a<b
user=> (s/def ::d (s/merge (s/keys :req [::a ::b]) ::a<b))
:user/d
user=> (s/explain-data ::d {::a 0 ::b 1})
nil
user=> (s/explain-data ::d {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/d :user/a<b], :in []}), :spec :user/d, :value #:user{:a 1, :b 0}}

Answer 1

_评论由：dchelimsky_发表

当引用谓词函数时，它也始终失败，因此让它工作唯一的办法是定义另一个规范并引用它。


user=> (defn a<b [a b] (< a b))
#'user/a<b
user=> (s/def ::e (s/merge (s/keys :req [::a ::b]) a<b))
:user/e
user=> (s/explain-data ::e {::a 1 ::b 2})
#:clojure.spec.alpha{:problems ({:path [], :pred user/a<b, :val #:user{:a 1, :b 2}, :via [:user/e], :in []}), :spec :user/e, :value #:user{:a 1, :b 2}}
user=> (s/explain-data ::e {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred user/a<b, :val #:user{:a 1, :b 0}, :via [:user/e], :in []}), :spec :user/e, :value #:user{:a 1, :b 0}}

Answer 2

评论由：alexmiller

（< (::a % ::b %)）看起来不对？#(< (::a %) (::b %)) 是否可行？

Answer 3

评论由：dchelimsky

这是一个很好的发现，但是没有 #(< (::a %) (::b %)) 在行内工作。我已经更新了示例以反映这一点。

Answer 4

评论由：dchelimsky

顺便说一下，在我打字错误之前，我已经在另一个地方缩小了问题范围。所以偶然地，无论是否有打字错误，我都得到了同一个答案。

Answer 5

_评论由：dchelimsky_发表

如果将谓词包裹在 {s/spec} 中，它确实可以工作。


user=> (s/def ::f (s/merge (s/keys :req [::a ::b]) (s/spec #(< (::a %) (::b %)))))
:user/f
user=> (s/explain-data ::f {::a 1 ::b 2})
nil
user=> (s/explain-data ::f {::a 1 ::b 0})
#:clojure.spec.alpha{:problems ({:path [], :pred (clojure.core/fn [%] (clojure.core/< (:user/a %) (:user/b %))), :val #:user{:a 1, :b 0}, :via [:user/f], :in []}), :spec :user/f, :value #:user{:a 1, :b 0}}

Answer 6

_评论由：jcr_

我无法重现这些问题。

在问题描述中，谓词 {{#(< (::a %) (::b %))}} 需要a小于b，所以预期的 {{::a 1 ::b 0}} 不符合规范。

在第一篇评论中，谓词 {{a<b}} 是无效的，因为它接受两个数字而不是单个映射。

以下片段也按预期工作（匿名谓词、命名谓词以及包裹在 s/spec 中的谓词之间没有区别）

(s/def ::a number?)
(defn good? [m] (contains? m :a))

(def s1 (s/merge (s/keys :req-un [::a]) good?))
(def s2 (s/merge (s/keys :req-un [::a]) #(contains? % :a)))
(def s3 (s/merge (s/keys :req-un [::a]) (s/spec #(contains? % :a))))

(s/valid? s1 {:a 42}) ;=> true
(s/valid? s2 {:a 42}) ;=> true
(s/valid? s3 {:a 42}) ;=> true


我认为可以关闭这个问题。

Answer 7

评论由：dchelimsky

在Alex评论后，我更新了示例，但我把消息放在了错误的位置。我刚刚又更新了一次，现在消息与输出的对齐是正确的。jcr，我看到你的例子能工作，但我的仍然不能。所以这并不仅仅与所有匿名谓词一样通用，但仍然有些令人惊讶的行为。

话虽如此，s/merge文档说明它支持keys规范，并不声称支持任何其他类型的谓词，因此如果您想要根据这些理由关闭它，请随意。

Answer 8

_评论由：jcr_

啊，我现在明白了你的意思。对不起我过于草率地下结论了。

所以这里实际的问题是，当使用未包裹在s/spec调用中的谓词与s/merge一起使用时，{{s/explain}}不一致地报告根据{{s/conform}}可用的输入。这里是我设法编译的最小示例


(ns test
  (:require [clojure.spec.alpha :as s]))

(defn pred [m] (contains? m :a))
(s/def ::s (s/merge pred))

(def good {:a 42})
(def bad  {})

;; 如预期的那样
(s/conform ::s good) ;=> {:a 42}
(s/conform ::s bad)  ;=> :clojure.spec.alpha/invalid

;; !!!: 第一个不应该失败
(s/explain-str ::s good) ;=> "val: {:a 42} fails spec: :test/s predicate: pred\n"
(s/explain-str ::s bad)  ;=> "val: {} fails spec: :test/s predicate: pred\n"

;; 明确地将pred包裹在spec中
(s/def ::s* (s/merge (s/spec pred)))

;; 现在，像预期的那样工作
(s/explain-str ::s* good) ;=> "Success!\n"
(s/explain-str ::s* bad)  ;=> "val: {} fails spec: :test/s* predicate: pred\n"


如果您不介意，我建议相应地更新标题和描述？

Answer 9

_评论由：jcr_

据我所知，问题是{{merge-spec-impl}}只是调用{{explain-1}}，并且当{{(spec? pred)}}为false时，{{explain-1}}总是返回问题；merge-spec-impl可能应该对其preds调用{{specize}}，类似于在{{tuple-impl}}中执行的方式


(let [specs (delay (mapv specize preds forms)) ...] ...)

Answer 10

参考：[https://clojure.atlassian.net/browse/CLJ-2321](https://clojure.atlassian.net/browse/CLJ-2321)（由dchelimsky报告）