我发现持久性集合之间的结构相等性很少做出假设，从而导致实现效率低下，特别是对于数组和映射。
实现的要点是通过方法直接遍历底层数组进行调度。
这些实现可能不是最漂亮的或最符合预期的，但它们是高效的。如果这样实现，在Java中看起来会不同。
我尝试了这些替代实现，并发现速度有显著提升
向量
(let [die (clojure.lang.Reduced. false)]
(defn vec-eq
[^PersistentVector v ^Iterable y]
(let [iy (.iterator y)]
(.reduce v (fn [_ x] (if (= x (.next iy)) true die)) true))))
当比较向量时，这可以用作向量x列表的算法
当前实现从0到count进行循环，并对每个元素调用nth。每次nth调用都调用arrayFor()，而reduce和迭代器只需每次数组一次。
映射
(let [o (Object.)
die (clojure.lang.Reduced. false)
eq (fn [m2] (fn [b k v]
(let [v' (.valAt ^IPersistentMap m2 k o)]
(if (.equals o v')
die
(if (= v v') true die)))))]
(defn map-eq
[m1 m2]
(.kvreduce ^IKVReduce m1 (eq m2) true)))
在这里，实现直接遍历底层的数组结构。
当前实现将数组强制转换为seq然后遍历它，同时通过Map接口从其他映射中获取条目。
此实现避免了将映射转换为序列，并且不会分配条目。
序列
当接收者是列表时，与之比较的对象和接收者都将被转换为序列。
使用迭代器将其他集合与它进行比较可能更有效
(defn iter-eq
[^Iterable x ^Iterable y]
(let [ix (.iterator x)
iy (.iterator y)]
(loop []
(if (.hasNext ix)
(if (= (.next ix) (.next iy))
(recur)
false)
true))))
基准测试
使用criterium，vec-eq赢得两种情况。随着大小的增加，收益递减，但n=64时，vec-eq的速度是=的两倍。
map-eq在较大的映射中也更快，速度提高2-3倍，在较小的映射中提高高达10倍。
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (vec (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (list* (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [m1 (zipmap (range n) (range n))
m2 (zipmap (range n) (range n))]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
补充说明
还检查了以下情况
(doseq [n [10000 100000]
:let [v1 (vec (range n))
v2 (assoc v1 (dec (count v1)) 7)]]
(cc/quick-bench (vec-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [100000]
:let [m1 (zipmap (range n) (range n))
m2 (assoc m1 (key (last m1)) 7)]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
优化后的实现仍以巨大的优势获胜
