我发现持久化集合之间的结构相等性假设很少导致低效实现，尤其是对于向量和映射。
实现的重点是通过方法直接遍历底层数组进行调度。
这些实现的代码可能不是最漂亮或最符合惯例的，但它们是高效的。如果这得以实现，在Java中看起来也会有所不同。
我尝试了这些替代实现，并发现了显著的加速
向量
(let [die (clojure.lang.Reduced. false)]
(defn vec-eq
[^PersistentVector v ^Iterable y]
(let [iy (.iterator y)]
(.reduce v (fn [_ x] (if (= x (.next iy)) true die)) true))))
当比较向量和向量加列表时，这效果很好
当前实现从0到count进行循环，并对每个元素调用nth。nth每次都会调用arrayFor()，而reduce和迭代器每次只获取一次数组的支持数组。
映射
(let [o (Object.)
die (clojure.lang.Reduced. false)
eq (fn [m2] (fn [b k v]
(let [v' (.valAt ^IPersistentMap m2 k o)]
(if (.equals o v')
die
(if (= v v') true die)))))]
(defn map-eq
[m1 m2]
(.kvreduce ^IKVReduce m1 (eq m2) true)))
在这里，实现也直接遍历底层数组的结构。
当前实现将数组转换为序列然后遍历它，同时通过Map接口从另一个映射中获取条目。
此实现避免了将映射转换为序列，并且不会分配条目。
序列
当接收者是列表时，与之比较的对象和接收者将被转换为序列。
与通过迭代器比较其他集合可能会更高效
(defn iter-eq
[^Iterable x ^Iterable y]
(let [ix (.iterator x)
iy (.iterator y)]
(loop []
(if (.hasNext ix)
(if (= (.next ix) (.next iy))
(recur)
false)
true))))
基准测试
使用criterium，vec-eq在两种情况下都获胜。随着大小增加，收益逐渐减少，但即使在n=64时，vec-eq的速度也是=的两倍。
map-eq在较大的映射中也是2-3倍快，在较小的映射中快10倍
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (vec (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (list* (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [m1 (zipmap (range n) (range n))
m2 (zipmap (range n) (range n))]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
补充
还检查了以下情况
(doseq [n [10000 100000]
:let [v1 (vec (range n))
v2 (assoc v1 (dec (count v1)) 7)]]
(cc/quick-bench (vec-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [100000]
:let [m1 (zipmap (range n) (range n))
m2 (assoc m1 (key (last m1)) 7)]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
优化实现仍然以巨大优势获胜
