我发现持久化集合之间的结构相等都做了很少的假设，这导致了效率不高的实现，尤其是对于数组和映射。
实现的重点是通过方法进行派发，这些方法直接迭代底层数组。
这些实现可能不是最漂亮或最常见的，但它们是高效的。如果真的这样实现了，Java中的表现方式可能也会不同。
我尝试了这些替代实现，并发现了显著的加速效果
向量
(let [die (clojure.lang.Reduced. false)]
(defn vec-eq
[^PersistentVector v ^Iterable y]
(let [iy (.iterator y)]
(.reduce v (fn [_ x] (if (= x (.next iy)) true die)) true))))
当比较向量和向量+x列表时，这个方法效果很好。
当前实现从0遍历到计数，并对每个元素调用nth。nth每次都调用arrayFor()，而reduce和迭代器每次数组都获取一次支持数组。
映射
(let [o (Object.)
die (clojure.lang.Reduced. false)
eq (fn [m2] (fn [b k v]
(let [v' (.valAt ^IPersistentMap m2 k o)]
(if (.equals o v')
die
(if (= v v') true die)))))]
(defn map-eq
[m1 m2]
(.kvreduce ^IKVReduce m1 (eq m2) true)))
在这里，实现也是直接迭代底层的数组结构。
当前实现将数组转换为seq，然后迭代它，同时通过Map接口从其他映射获取条目。
这个实现避免了将映射转换为序列，并且没有分配条目。
序列
当接收者是列表时，与之比较的对象以及接收者都将转换为seq。
通过迭代器与其他集合进行比较可能更高效。
(defn iter-eq
[^Iterable x ^Iterable y]
(let [ix (.iterator x)
iy (.iterator y)]
(loop []
(if (.hasNext ix)
(if (= (.next ix) (.next iy))
(recur)
false)
true))))
基准测试
使用criterium，vec-eq在两种情况下都赢了。随着大小的增加，收益递减，但是当n=64时，vec-eq是=的两倍。
map-eq在大映射中快2-3倍，在小映射中快至10倍
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (vec (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (list* (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [m1 (zipmap (range n) (range n))
m2 (zipmap (range n) (range n))]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
附录
还检查了以下情况
(doseq [n [10000 100000]
:let [v1 (vec (range n))
v2 (assoc v1 (dec (count v1)) 7)]]
(cc/quick-bench (vec-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [100000]
:let [m1 (zipmap (range n) (range n))
m2 (assoc m1 (key (last m1)) 7)]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
优化实现仍然以巨大的差距获胜
