我发现持久化集合之间的结构相等性几乎不进行任何假设，这导致了效率低下的实现，尤其是对于数组和映射。
实现的焦点是通过方法进行分发，这些方法直接迭代底层数组。
这些实现在美观和的传统风格上并不出色，但它们很有效。如果这被实现，Java中的实现将看起来不同。
我尝试了这些替代实现，并发现速度提升了很大
向量
(let [die (clojure.lang.Reduced. false)]
(defn vec-eq
[^PersistentVector v ^Iterable y]
(let [iy (.iterator y)]
(.reduce v (fn [_ x] (if (= x (.next iy)) true die)) true))))
这在对向量进行比较时效果很好，对于向量x列表也是如此
当前实现从0到count进行循环调用nth，为每个元素调用nth。nth每次都调用arrayFor()，而reduce和迭代器每个数组只获取一次后备数组。
映射
(let [o (Object.)
die (clojure.lang.Reduced. false)
eq (fn [m2] (fn [b k v]
(let [v' (.valAt ^IPersistentMap m2 k o)]
(if (.equals o v')
die
(if (= v v') true die)))))]
(defn map-eq
[m1 m2]
(.kvreduce ^IKVReduce m1 (eq m2) true)))
在这里，实现也直接迭代底层的数组结构。
当前实现将数组转换为序列，然后迭代它，通过Map接口从另一个映射中获取条目。
这种实现避免了将映射转换为序列，并且不会分配条目。
序列
当接收者是列表时，与之比较的对象和接收者将被转换为seq。
通过迭代器与其它集合比较可能会更有效
(defn iter-eq
[^Iterable x ^Iterable y]
(let [ix (.iterator x)
iy (.iterator y)]
(loop []
(if (.hasNext ix)
(if (= (.next ix) (.next iy))
(recur)
false)
true))))
基准测试
使用criterium，vec-eq在这两种情况下都获胜。随着大小的增加， 收益递减，但即使在n=64时，vec-eq也比=快两倍。
对于较大的映射，map-eq的速度也能快2-3倍，对于较小的映射，速度能快10倍。
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (vec (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (list* (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [m1 (zipmap (range n) (range n))
m2 (zipmap (range n) (range n))]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
补充说明
还检查了以下情况
(doseq [n [10000 100000]
:let [v1 (vec (range n))
v2 (assoc v1 (dec (count v1)) 7)]]
(cc/quick-bench (vec-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [100000]
:let [m1 (zipmap (range n) (range n))
m2 (assoc m1 (key (last m1)) 7)]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
优化实现仍然具有巨大的优势
