我发现持久化集合间的结构相等都做很少的假设，这导致实现效率低下，尤其是对于向量和映射。
实现的核心是通过对基本数组进行迭代的方法来进行分派。
这些实现可能看起来不太美观或不那么符合惯例，但它们是高效的。无论如何，如果它在Java中实现，它的模样可能都不同。
我尝试了这些替代实现，并发现速度有了显著提升
向量
(let [die (clojure.lang.Reduced. false)]
(defn vec-eq
[^PersistentVector v ^Iterable y]
(let [iy (.iterator y)]
(.reduce v (fn [_ x] (if (= x (.next iy)) true die)) true))))
当比较向量和向量与列表时，这很有效。
当前的实现通过0到计数的循环，并对每个元素调用nth。nth每次都调用arrayFor()，而reduce和迭代器每个数组只获取一次支持数组。
映射
(let [o (Object.)
die (clojure.lang.Reduced. false)
eq (fn [m2] (fn [b k v]
(let [v' (.valAt ^IPersistentMap m2 k o)]
(if (.equals o v')
die
(if (= v v') true die)))))]
(defn map-eq
[m1 m2]
(.kvreduce ^IKVReduce m1 (eq m2) true)))
在这里，实现也直接遍历基本数组结构。
当前的实现将数组转换为序列然后迭代它，同时通过Map接口从另一个映射获取条目。
此实现避免将映射转换为序列，并且不会分配条目。
序列
当接收者是列表时，要比较的对象和接收者将被转换为序列。
通过迭代器比较其他集合可能更有效。
(defn iter-eq
[^Iterable x ^Iterable y]
(let [ix (.iterator x)
iy (.iterator y)]
(loop []
(if (.hasNext ix)
(if (= (.next ix) (.next iy))
(recur)
false)
true))))
基准测试
使用criterium，vec-eq在两种情况下都获胜。随着大小的增加，收益递减，但仍然在n=64时，vec-eq比=快两倍。
map-eq对于较大的映射也是2-3倍快，对于较小的映射可高达10倍快
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (vec (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (list* (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [m1 (zipmap (range n) (range n))
m2 (zipmap (range n) (range n))]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
补充
还检查了以下情况
(doseq [n [10000 100000]
:let [v1 (vec (range n))
v2 (assoc v1 (dec (count v1)) 7)]]
(cc/quick-bench (vec-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [100000]
:let [m1 (zipmap (range n) (range n))
m2 (assoc m1 (key (last m1)) 7)]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
优化后的实现仍以巨大的优势获胜
