我发现持久性集合之间的结构等性做出了非常少的假设，这导致了低效的实现，特别是对于向量和映射。
实现的要点是通过方法直接迭代底层数组进行分发。
这些实现可能不是最漂亮的或最符合惯例的，但它们是高效的。如果用Java实现，看起来会不同。
我尝试了这些替代实现，并发现速度有了显著提升
向量
(let [die (clojure.lang.Reduced. false)]
(defn vec-eq
[^PersistentVector v ^Iterable y]
(let [iy (.iterator y)]
(.reduce v (fn [_ x] (if (= x (.next iy)) true die)) true))))
当比较向量和向量与列表时，这效果很好。
当前实现通过从0到count的循环调用nth，每个元素调用一次。nth每次都调用arrayFor()，而reduce和迭代器每次只从底层数组获取一次。
映射
(let [o (Object.)
die (clojure.lang.Reduced. false)
eq (fn [m2] (fn [b k v]
(let [v' (.valAt ^IPersistentMap m2 k o)]
(if (.equals o v')
die
(if (= v v') true die)))))]
(defn map-eq
[m1 m2]
(.kvreduce ^IKVReduce m1 (eq m2) true)))
在这里，实现也直接遍历底层数组结构。
当前实现将数组转换为序列，然后迭代它，同时通过Map接口从另一个映射获取条目。
此实现避免了将映射转换为序列，并且没有分配条目。
序列
当接收者是列表时，与其比较的对象和接收者将被转换为序列。
通过与迭代器比较其他集合可能更高效。
(defn iter-eq
[^Iterable x ^Iterable y]
(let [ix (.iterator x)
iy (.iterator y)]
(loop []
(if (.hasNext ix)
(if (= (.next ix) (.next iy))
(recur)
false)
true))))
基准测试
使用criterium，vec-eq在两种情况下都获胜。随着大小的增加，收益递减，但即使在n=64处，vec-eq的速度也比=快两倍。
map-eq对于较大的映射也要快2-3倍，对于较小的映射要快10倍以上。
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (vec (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [v1 (vec (range n))
v2 (list* (range n))]]
(println 'iter-eq n (iter-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(println 'vec-eq n (vec-eq v1 v2))
(cc/quick-bench (vec-eq v1 v2))
(println '= n (= v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [1 2 4 8 16 32 64]
:let [m1 (zipmap (range n) (range n))
m2 (zipmap (range n) (range n))]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
追加
还检查了以下情况
(doseq [n [10000 100000]
:let [v1 (vec (range n))
v2 (assoc v1 (dec (count v1)) 7)]]
(cc/quick-bench (vec-eq v1 v2))
(cc/quick-bench (iter-eq v1 v2))
(cc/quick-bench (= v1 v2)))
(doseq [n [100000]
:let [m1 (zipmap (range n) (range n))
m2 (assoc m1 (key (last m1)) 7)]]
(cc/quick-bench (map-eq m1 m2))
(cc/quick-bench (= m1 m2)))
优化的实现仍然以压倒性的优势获胜
