"concat" 两个 xforms 为一？

Question

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (concat
    (into [] xf1 coll)
    (into [] xf2 coll)))

有没有将上面两个 xforms（xf1 和 xf2）以某种方式组合成一个，以便只遍历一次 collection coll 的方法？

Answer 1

实际上不是 transducers 的组合，但

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 #(-> % :a #{1 3})
      xf2 #(-> % :b #{2 4})] 
  (into []
    (comp 
      (mapcat (juxt xf1 xf2))
      (remove nil?))
    coll))
=> [1 2 3 4 1 4]

Comments

好的尝试，但我正在寻找一种组合 transducers 的方法...

Answer 2

  (let [coll [{:a 1 :b 2}
              {:a 3 :b 4}
              {:a 7 :b 5}
              {:a 1 :b 4}]
        xf1 (comp (map :a) (filter #{1 3}))
        xf2 (comp (map :b) (filter #{2 4}))]
    (eduction cat [(eduction xf1 coll) (eduction xf2 coll)]))

eduction可以用sequence代替

Answer 3

(defn facet [m]
  (fn [f]
    (let [m (into {} (for [[k v] m]
                       [k (v f)]))]
      (fn
        ([accum]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2)))
          accum
          accum))
        ([accum value]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2 value)))
          accum
          accum))))))

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  ((comp (partial apply concat)
         (juxt :a :b))
   (transduce
    (facet {:a xf1
            :b xf1})
    conj
    {:a []
     :b []}
    coll)))

Comments

查找有趣的转换器的好地方是https://github.com/cgrand/xforms，以及获取不同类型折叠处理灵感的好地方是https://github.com/aphyr/tesser

Answer 4

哎呀，我发现我实际上没有回答你的问题。我将我的原始问题移到评论中。

使用cgrand/xforms，可能的答案是

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (= (concat
      (into [] xf1 coll)
      (into [] xf2 coll))
     
     ;; do it in one pass
     (x/into []
       (comp (x/transjuxt [(comp xf1 (x/into [])) (comp xf2 (x/into []))])
             cat
             cat)
       coll)))

Comments

好事是这里有个搜索功能。我最近遇到了类似的情况，我想对不同输入集合并在一起进行处理，最后得到一个集合，所以我试了几个不同的方法。

下面是这个例子中的REPL会话。我使用了criterium进行了一段时间的性能测试后，得出结论：通过多个`into`来穿引集合的方法可能是最地道的，而且其性能并不比`catreduce`差。

    (def input1 (into [] (range 100000)))
    (def input2 (into [] (range 999 9999)))
    (def xf1 (filter odd?))
    (def xf2 (map inc))
    (def xf3 (take 100))
    (def xf4 (comp (filter even?) (map dec) (take 1000)))
  
    ;; concat (不喜欢它懒惰和分配了多个中间集合)
    (def result (into []
                       (concat
                            (into [] xf1 input1)
                            (into [] xf2 input1)
                            (into [] xf3 input2)
                       (into [] xf4 input2))))
  
    ;; cat (仍然分配中间集合)
    (= result
       (into []
             cat
             [(into [] xf1 input1)
              (into [] xf2 input1)
              (into [] xf3 input2)
              (into [] xf4 input2)]))
  
    ;; intos (没有分配中间资源，但有多次瞬态/持久切换)
    ;; - 但这应该不是太大问题，因为它们的复杂度都是O(1)
    (= result
       (-> []
             (into xf1 input1)
             (into xf2 input1)
             (into xf3 input2)
             (into xf4 input2)))
  
    ;; reduce into
    ;; - 几乎与intos解决方案相同，无需多次调用into
    (= result
       (reduce
         #(into %1 (second %2) (first %2))
         []
         [[input1 xf1]
          [input1 xf2]
          [input2 xf3]
          [input2 xf4]]))
  
    ;; catreduce
    ;; - 尝试查看是否可以不进行许多瞬态/持久切换就完成它
    (defn catduce
      "借鉴自clojure.core/cat"
      [rf]
      (fn
        ([] (rf))
        ([result] (rf result))
        ([result input+xf]
         (transduce (second input+xf) rf result (first input+xf)))))
  
    (= result
       (into [] catduce
             [[input1 xf1]
              [input1 xf2]
              [input2 xf3]
              [input2 xf4]]))