"concat" 两个 xforms 为一个？

Question

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (concat
    (into [] xf1 coll)
    (into [] xf2 coll)))

有没有一种方法将上述两个 xform（xf1 和 xf2）组合成一个单一的 xform，这样集合 coll 就只被遍历一次？

Answer 1

这并不是将它俩合并为 transducers，但……

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 #(-> % :a #{1 3})
      xf2 #(-> % :b #{2 4})] 
  (into []
    (comp 
      (mapcat (juxt xf1 xf2))
      (remove nil?))
    coll))
=> [1 2 3 4 1 4]

Comments

虽然试过了，但我正在寻找合并 transducers 的方法……

Answer 2

  (let [coll [{:a 1 :b 2}
              {:a 3 :b 4}
              {:a 7 :b 5}
              {:a 1 :b 4}]
        xf1 (comp (map :a) (filter #{1 3}))
        xf2 (comp (map :b) (filter #{2 4}))]
    (eduction cat [(eduction xf1 coll) (eduction xf2 coll)]))

可以将 eduction 替换为 sequence。

Answer 3

(defn facet [m]
  (fn [f]
    (let [m (into {} (for [[k v] m]
                       [k (v f)]))]
      (fn
        ([accum]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2)))
          accum
          accum))
        ([accum value]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2 value)))
          accum
          accum))))))

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  ((comp (partial apply concat)
         (juxt :a :b))
   (transduce
    (facet {:a xf1
            :b xf1})
    conj
    {:a []
     :b []}
    coll)))

Comments

寻找有趣的转换器的好地方是 https://github.com/cgrand/xforms，而想创意不同种类的折叠处理的方法，可以参考 https://github.com/aphyr/tesser。

Answer 4

哎呀，我发现我实际上并没有回答你的问题。我将我的原始问题移入评论中。

使用 cgrand/xforms，可能的一个答案是

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (= (concat
      (into [] xf1 coll)
      (into [] xf2 coll))
     
     ;; do it in one pass
     (x/into []
       (comp (x/transjuxt [(comp xf1 (x/into [])) (comp xf2 (x/into []))])
             cat
             cat)
       coll)))

Comments

这里有一个搜索功能，是个好事。我最近遇到类似的场景，我想要在几个输入集合上执行不同的转换，最终得到一个集合，所以我尝试了几种不同的方法。

下面是我的 REPL 会话。经过一些基本的性能测试后，我得出结论，通过多个 `into` 线程集合的解决方案可能是最习惯性的，并且在性能方面并不比 `catduce` 差。

    (def input1 (into [] (range 100000)))
    (def input2 (into [] (range 999 9999)))
    (def xf1 (filter odd?))
    (def xf2 (map inc))
    (def xf3 (take 100))
    (def xf4 (comp (filter even?) (map dec) (take 1000)))
  
    ;; 连接 (不喜欢它懒惰且分配了多个中间集合)
    (def result (into []
                      (concat
                       (into [] xf1 input1)
                       (into [] xf2 input1)
                       (into [] xf3 input2)
                       (into [] xf4 input2))))
  
    ;; cat (仍然会分配中间集合)
    (= result
       (into []
             cat
             [(into [] xf1 input1)
                   (into [] xf2 input1)
                   (into [] xf3 input2)
                   (into [] xf4 input2)]))
  
    ;; intos (没有中间分配，但有多个暂态/持久切换)
    ;; - 这不应该是个大问题，因为它们都是 O(1))
    (= result
       (-> []
             (into xf1 input1)
             (into xf2 input1)
             (into xf3 input2)
             (into xf4 input2)))
  
    ;; reduce into
    ;; - 几乎与intos解法相同，无需多次编写into)
    (= result
       (reduce
         #(into %1 (second %2) (first %2))
         []
         [[input1 xf1]
          [input1 xf2]
          [input2 xf3]
          [input2 xf4]]))
  
    ;; catduce
    ;; - 试图看是否可以在避免许多暂态/持久切换的情况下完成
    (defn catduce
      "从clojure.core/cat借用"
      [rf]
      (fn
        ([] (rf))
        ([result] (rf result))
        ([result input+xf]
         (transduce (second input+xf) rf result (first input+xf)))))
  
    (= result
       (into [] catduce
             [[input1 xf1]
                   [input1 xf2]
                   [input2 xf3]
                   [input2 xf4]]))