如何将两个xforms合并成为一个？

Question

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (concat
    (into [] xf1 coll)
    (into [] xf2 coll)))

有没有一种方法可以将上面的两个xforms（xf1和xf2）合并成一个，这样coll集合就只需遍历一次？

Answer 1

这并不是转置的合并，但

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 #(-> % :a #{1 3})
      xf2 #(-> % :b #{2 4})] 
  (into []
    (comp 
      (mapcat (juxt xf1 xf2))
      (remove nil?))
    coll))
=> [1 2 3 4 1 4]

Comments

你的尝试很棒，但我正在寻找合并转置的方法...

Answer 2

  (let [coll [{:a 1 :b 2}
              {:a 3 :b 4}
              {:a 7 :b 5}
              {:a 1 :b 4}]
        xf1 (comp (map :a) (filter #{1 3}))
        xf2 (comp (map :b) (filter #{2 4}))]
    (eduction cat [(eduction xf1 coll) (eduction xf2 coll)]))

可以将eduction替换为sequence。

Answer 3

(defn facet [m]
  (fn [f]
    (let [m (into {} (for [[k v] m]
                       [k (v f)]))]
      (fn
        ([accum]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2)))
          accum
          accum))
        ([accum value]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2 value)))
          accum
          accum))))))

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  ((comp (partial apply concat)
         (juxt :a :b))
   (transduce
    (facet {:a xf1
            :b xf1})
    conj
    {:a []
     :b []}
    coll)))

Comments

寻找有趣转换子的好地方是 https://github.com/cgrand/xforms，而对于不同种类的折叠处理，以下链接是为灵感的来源： https://github.com/aphyr/tesser

Answer 4

哎呀，我发现我实际上并没有回答你的问题。我把原问题移动到了评论中。

使用 cgrand/xforms，可能的答案是

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (= (concat
      (into [] xf1 coll)
      (into [] xf2 coll))
     
     ;; do it in one pass
     (x/into []
       (comp (x/transjuxt [(comp xf1 (x/into [])) (comp xf2 (x/into []))])
             cat
             cat)
       coll)))

Comments

这里有一个搜索功能真是好事。我最近遇到了类似的情况，我想对几个输入集合执行不同的转换，并最终得到一个集合，所以我尝试了几种不同的方法。

以下是我的交互式Python会话。在进行了一些基本的性能测试后，我得出结论，使用 `into` 链接集合的方案可能是最具表现力的，而且在性能方面并不比 `catduce` 差。

    ；(def input1 (into [] (range 100000)))
    ；(def input2 (into [] (range 999 9999)))
    ；(def xf1 (filter odd?))
    ；(def xf2 (map inc))
    (def xf3 (take 100))
    (def xf4 (comp (filter even?) (map dec) (take 1000)))
  
    ;; concat (不喜歡它的懒惰性和分配了多个中间集合)
    (def result (into []
                      (concat
                       (into [] xf1 input1)
                       (into [] xf2 input1)
                       (into [] xf3 input2)
                       (into [] xf4 input2))))
  
    ;; cat (仍然分配中间集合)
    (= result
       (into []
             cat
             [(into [] xf1 input1)
              (into [] xf2 input1)
              (into [] xf3 input2)
              (into [] xf4 input2)]))
  
    ;; intos (没有中间分配，但是多次暂时/持久切换)
    ;; - 但是这不应该是个大问题，因为它们都是 O(1))
    (= result
       (-> []
           (into xf1 input1)
           (into xf2 input1)
           (into xf3 input2)
           (into xf4 input2)))
  
    ;; reduce into
    ;; - 几乎与 intos 解决方案相同，无需多次编写 into)
    (= result
       (reduce
         #(into %1 (second %2) (first %2))
         []
         [[input1 xf1]
          [input1 xf2]
          [input2 xf3]
          [input2 xf4]]))
  
    ;; catduce
    ;; - 尝试看是否可以在不进行许多暂时/持久切换的情况下完成)
    (defn catduce
      "从 clojure.core/cat 采纳"
      [rf]
      (fn
        ([] (rf))
        ([result] (rf result))
        ([result input+xf]
         (transduce (second input+xf) rf result (first input+xf)))))
  
    (= result
       (into [] catduce
             [[input1 xf1]
              [input1 xf2]
              [input2 xf3]
              [input2 xf4]]))