将两个xforms合并为一个？

Question

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (concat
    (into [] xf1 coll)
    (into [] xf2 coll)))

有没有一种方法可以以某种方式将上面的两个xforms（xf1和xf2）组合成一个单一的一元算子，这样集合coll将被遍历 pouze jednou?

Answer 1

这不是一元算子的组合，但

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 #(-> % :a #{1 3})
      xf2 #(-> % :b #{2 4})] 
  (into []
    (comp 
      (mapcat (juxt xf1 xf2))
      (remove nil?))
    coll))
=> [1 2 3 4 1 4]

Comments

尝试一下很好，但我正在寻找一种组合一元算子的方法...

Answer 2

  (let [coll [{:a 1 :b 2}
              {:a 3 :b 4}
              {:a 7 :b 5}
              {:a 1 :b 4}]
        xf1 (comp (map :a) (filter #{1 3}))
        xf2 (comp (map :b) (filter #{2 4}))]
    (eduction cat [(eduction xf1 coll) (eduction xf2 coll)]))

将eduction替换为sequence

Answer 3

(defn facet [m]
  (fn [f]
    (let [m (into {} (for [[k v] m]
                       [k (v f)]))]
      (fn
        ([accum]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2)))
          accum
          accum))
        ([accum value]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2 value)))
          accum
          accum))))))

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  ((comp (partial apply concat)
         (juxt :a :b))
   (transduce
    (facet {:a xf1
            :b xf1})
    conj
    {:a []
     :b []}
    coll)))

Comments

寻找有趣的转换器的好地方是 https://github.com/cgrand/xforms，关于如何使用折叠来完成各种处理的灵感可以来自 https://github.com/aphyr/tesser

Answer 4

哎呀，我发现我实际上没有回答你的问题。我把我最初的问题移到了评论中。

使用cgrand/xforms，一个可能的答案是

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (= (concat
      (into [] xf1 coll)
      (into [] xf2 coll))
     
     ;; do it in one pass
     (x/into []
       (comp (x/transjuxt [(comp xf1 (x/into [])) (comp xf2 (x/into []))])
             cat
             cat)
       coll)))

Comments

遗憾的是这里有一个搜索功能。我最近遇到了类似的情况，我想对几个输入集合进行不同的转换，然后得到一个集合，所以我试了几种不同的方法。

这是我的REPL会话。使用criterium进行了一些基本的性能测试后，我得出结论，通过多个`into`来传递集合的解决方案可能是最符合习惯的，并且它的性能并不比`catduce`差。

    (def input1 (into [] (range 100000)))
    (def input2 (into [] (range 999 9999)))
    (def xf1 (filter odd?))
    (def xf2 (map inc))
    (def xf3 (take 100))
    (def xf4 (comp (filter even?) (map dec) (take 1000)))
  
    ;; concat (不喜其惰性且分配了多个中间集合)
    (def result (into []
                         (concat
                               (into [] xf1 input1)
                               (into [] xf2 input1)
                               (into [] xf3 input2)
                               (into [] xf4 input2))))
  
    ;; cat (仍会分配中间集合)
    (= result
               (into []
                     (cat
                       [(into [] xf1 input1)
                       [(into [] xf2 input1)
                       [(into [] xf3 input2)
                       [(into [] xf4 input2)]))))
  
    ;; intos (没有中间分配，但需要进行多次短暂的持久性切换)
    ;; - 这种情况不应该太大问题，因为它们都是 O(1) 的)
    (= result
       (-> []
                  (into xf1 input1)
                  (into xf2 input1)
                  (into xf3 input2)
                  (into xf4 input2)))
  
    ;; reduce into
    ;; - 几乎和 intos 解决方案相同，无需多次写入 into)
    (= result
       (reduce
         #(into %1 (second %2) (first %2))
         []
         [[input1 xf1]
          [input1 xf2]
          [input2 xf3]
          [input2 xf4]]))
  
    ;; catduce
    ;; - 尝试看看是否可以在不进行多次短暂的持久性切换的情况下完成
    (defn catduce
      "借鉴自 clojure.core/cat"
      [rf]
      (fn
        ([] (rf))
        ([result] (rf result))
        ([result input+xf]
         (transduce (second input+xf) rf result (first input+xf)))))
  
    (= result
       (into [] catduce
             [[input1 xf1]
              [input1 xf2]
              [input2 xf3]
              [input2 xf4]]))