"合并两个xform进一个？

Question

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (concat
    (into [] xf1 coll)
    (into [] xf2 coll)))

有没有一种方法可以将上面的两个xform (xf1 和 xf2) 合并成一个单个的xform，使得集合 coll 只被访问一次？

Answer 1

不是很转换器的组合，但

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 #(-> % :a #{1 3})
      xf2 #(-> % :b #{2 4})] 
  (into []
    (comp 
      (mapcat (juxt xf1 xf2))
      (remove nil?))
    coll))
=> [1 2 3 4 1 4]

Comments

挺好的尝试，但我正在寻找合并转换器的方法...

Answer 2

  (let [coll [{:a 1 :b 2}
              {:a 3 :b 4}
              {:a 7 :b 5}
              {:a 1 :b 4}]
        xf1 (comp (map :a) (filter #{1 3}))
        xf2 (comp (map :b) (filter #{2 4}))]
    (eduction cat [(eduction xf1 coll) (eduction xf2 coll)]))

将 eduction 替换为 sequence

Answer 3

(defn facet [m]
  (fn [f]
    (let [m (into {} (for [[k v] m]
                       [k (v f)]))]
      (fn
        ([accum]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2)))
          accum
          accum))
        ([accum value]
         (reduce
          (fn [accum1 [k accum2]]
            (assoc accum1 k ((get m k) accum2 value)))
          accum
          accum))))))

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  ((comp (partial apply concat)
         (juxt :a :b))
   (transduce
    (facet {:a xf1
            :b xf1})
    conj
    {:a []
     :b []}
    coll)))

Comments

寻找有趣的转换器的良好地点是 https://github.com/cgrand/xforms，而针对不同类型的折叠处理可以得到灵感的良好地点是 https://github.com/aphyr/tesser

Answer 4

哎呀，我意识到我没有真正回答你的问题。我将我原来的问题移到一个评论中。

使用cgrand/xforms，一个可能的答案可以是

(let [coll [{:a 1 :b 2}
            {:a 3 :b 4}
            {:a 7 :b 5}
            {:a 1 :b 4}]
      xf1 (comp (map :a) (filter #{1 3}))
      xf2 (comp (map :b) (filter #{2 4}))]
  (= (concat
      (into [] xf1 coll)
      (into [] xf2 coll))
     
     ;; do it in one pass
     (x/into []
       (comp (x/transjuxt [(comp xf1 (x/into [])) (comp xf2 (x/into []))])
             cat
             cat)
       coll)))

Comments

这里有一个搜索功能。我最近遇到了类似的情景，我想对几个输入集合执行不同的转换，最后成为一个集合，所以我尝试了几种不同的方法。

这是我的REPL会话。在用criterium进行一些基本的性能测试之后，我得出结论，将集合通过多个 `into` 进行操作的解决方案可能是最符合习惯的，并且其性能并不比 `catduce` 差。

    (def input1 (into [] (range 100000)))
    (def input2 (into [] (range 999 9999)))
    (def xf1 (filter odd?))
    (def xf2 (map inc))
    (def xf3 (take 100))
    (def xf4 (comp (filter even?) (map dec) (take 1000)))
  
    ;; concat (不喜欢它是懒加载并且创建了多个中间集合)
    (def result (into []
                       (concat
                        (into [] xf1 input1)
                        (into [] xf2 input1)
                        (into [] xf3 input2)
                       (into [] xf4 input2))))
  
    ;; cat (仍然创建中间集合)
    (= result
       (into []
             cat
             [(into [] xf1 input1)
              (into [] xf2 input1)
              (into [] xf3 input2)
              (into [] xf4 input2)]))
  
    ;; intos (没有中间分配，但是有很多悬而未决的/持久切换)
    ;; - 然而，它们都是 O(1)，所以这不应该成问题
    (= result
       (-> []
             (into xf1 input1)
             (into xf2 input1)
             (into xf3 input2)
             (into xf4 input2)))
  
    ;; reduce into
    ;; - 几乎与 intos 解决方案相同，无需多次写入 into
    (= result
       (reduce
         #(into %1 (second %2) (first %2))
         []
         [[input1 xf1]
          [input1 xf2]
          [input2 xf3]
          [input2 xf4]]))
  
    ;; catduce
    ;; - 尝试看看是否可以不使用许多暂时性的/持久的切换来完成
    (defn catduce
      "借鉴自 clojure.core/cat"
      [rf]
      (fn
        ([] (rf))
        ([result] (rf result))
        ([result input+xf]
         (transduce (second input+xf) rf result (first input+xf)))))
  
    (= result
       (into [] catduce
             [[input1 xf1]
              (into [] xf2 input1)
              (into [] xf3 input2)
              (into [] xf4 input2)]))