如何有条件地更新地图元素？

Question

我有一些代码，它将一种数据结构从一种格式转换成另一种格式（SVG hiccup 属性到 CLJFX 属性）。格式非常相似，但是在属性存在的情况下，我偶尔需要对其进行一些调整。例如，可能需要将字符串（read-string ..）读成一个数字，或者更新一个关键字以便拼写得更正确，等等。

现在我的代码形式如下

(-> svg-attributes
  (update :stroke #(case %
                     nil :black
                     "none" :black
                     (if (= \# %)
                       %
                       (keyword %))))
  (update :fill #(case %
                   nil "transparent"
                   "none" "transparent"
                   (if (= \# %)
                     %
                     (keyword %))))
  (update :points #(case %
                     nil []
                     [] []
                     (map read-string (-> %
                                          (clojure.string/split #"[ ,]")))))
  (update :stroke-width #(case %
                           nil 1.0
                           %))
  (update :stroke-dasharray #(case %
                               nil []
                               (map read-string (-> %
                                                    (clojure.string/split #"[ ,]")))))
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array})
  (update :font-size #(case %
                        nil 10
                        "none" 10
                        %))))

问题是，我不得不一直捕获 nil 的情况并强行插入一些默认值……这在大多数情况下是可行的……但我想在没有任何更新内容时跳过更新。

我看到这个问题，它与这个问题非常相似：https://ask.clojure.org/index.php/8387/how-to-avoid-nil-values-in-maps

在每一行使用 (cond-> 与 (some? (:somekeyword %)) 是否是惯用的解决方案？我觉得我并没有找到合适的工具！也许有人可以给我更好的建议：）

Answer 1

我在几个项目中见过手写的 update-if-exists 变体，这里是在 medley 工具库中的示例实现。

AFAIK，Clojure 核心库中没有这样的东西。

Comments

这正是我所怀疑的。我想再确认一下。有时我会看到一些地图处理技巧，我会学到一个新的技巧 :)

Answer 2

update-if-exists 是一个值得了解的点，但是在这里可能并不会完全解决问题..

原始程序的主要和根本问题是，它将每个键的逻辑和地图更新逻辑纠缠在一起，从而模糊了转换的本质（例如，键和值都发生变化）以及翻译之间的关系（是否后续的翻译依赖于早期的翻译）。

将两个关注点分开，每一个都更容易进行改进。

要转换1个属性，你可以有一个函数（可能是多方法），或者一个查找表。例如，假设你有一个函数 svg->cljfx，它接受一个 [k v]（例如，映射条目）并生成一个新的 [k v]；那么整个 svg-attributes 的转换可以通过以下方式完成

(->> svg-attributes
     (map svg->cljfx)
     (into {}))

易于阅读，但是对于未改变属性比改变属性多的情形，CPU效率并不是非常高。

另一方面，假设你有一个svg键到函数（可能是匿名函数）的查找表，该函数返回一个新的 [key value] 对。循环可以遍历已知的转换。它将跳过缺失的键，但至少这种情况可以一劳永逸地解决，而不是每个键都解决一次。逻辑会更加复杂，但它可能会更快地运行。

Comments

顺便说一下，你在使用 `edn/read-string` 吗？核心中的 `read-string` 值得避免，除非你确实需要它的副作用。

---

哦，对于键值对的映射很巧妙！我完全忘记了你可以这样使用`map`！感谢你的建议。我有点喜欢这个解决方案，尽管多方法将会有些冗长，因为每次它只返回一个键。尽管如此，它比我的解决方案更简洁。

Answer 3

如果所有默认值都是"值"，并且函数处于尾调用位置，这将这样做

(defn set-defaults [v m f]
  (or (get m v) (f v)))

(defn points [s]
  (mapv read-string (clojure.string/split s #"[ ,]")))

(-> {:points    "1,2,3,4"
     :stroke    \#
     :font-size "none"}
  (update :stroke set-defaults {nil :black "none" :black \# \#} keyword)
  (update :fill set-defaults {nil "transparent" "none" "transparent" \# \#} keyword)
  (update :points set-defaults {nil [] [] []} points)
  (update :stroke-width set-defaults {nil 1.0} identity)
  (update :stroke-dasharray set-defaults {nil []} points)
  (update :font-size set-defaults {nil 10 "none" 10} identity)
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array}))

;=>
{:points            [1 2 3 4]
 :stroke            \#
 :font-size         10
 :fill              "transparent"
 :stroke-width      1.0
 :stroke-dash-array []}

或者，如果任何默认值也可以是函数

(defn set-defaults2 [v m defaultf]
  (let [f (get m v defaultf)]
    (f v)))

(-> {} 
  (update :stroke set-defaults2 {nil (constantly :black)}))

当然，在`condp`中还有一个`>>>` "特性"：https://docs.clojure.org/clojure.core/condp#example-542692cbc026201cdc326be4

Answer 4

如果你愿意更新等于`nil`的现有值

(update your-map (fnil identity :default-value))