如何有条件地更新地图元素？

Question

我有一些代码，用于将一种格式的数据结构转换为另一种格式（从 SVG hiccup 属性到 CLJFX 属性）。这些格式非常相似，但当我处理属性时，有时需要对其进行一些修改。例如，可能需要将字符串（read-string ..）转换成数字，或者更新一个关键字使其拼写略有不同等等。

目前我的代码是这样的

(-> svg-attributes
  (update :stroke #(case %
                     nil :black
                     "none" :black
                     (if (= \# %)
                       %
                       (keyword %))))
  (update :fill #(case %
                   nil "transparent"
                   "none" "transparent"
                   (if (= \# %)
                     %
                     (keyword %))))
  (update :points #(case %
                     nil []
                     [] []
                     (map read-string (-> %
                                          (clojure.string/split #"[ ,]")))))
  (update :stroke-width #(case %
                           nil 1.0
                           %))
  (update :stroke-dasharray #(case %
                               nil []
                               (map read-string (-> %
                                                    (clojure.string/split #"[ ,]")))))
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array})
  (update :font-size #(case %
                        nil 10
                        "none" 10
                        %))))

问题在于我总是需要捕获 nil 的情况并添加一些默认值...这大多数时候都有效，但我不希望在不进行更新时更新元素。

我看到了这个问题，它与我的情况非常相似： https://ask.clojure.org/index.php/8387/how-to-avoid-nil-values-in-maps

将 (cond-> 与每个行的 (some? (:somekeyword %)) 结合起来是否是惯用的解决方案？我觉得我可能没有找到合适的工具！也许有人可以给我更好的建议 :)

Answer 1

我在几个项目中看到了自己编写的 update-if-exists 变体，这里是 util 库 medley 中实现的示例。

AFAIK，Clojure 核心中不存在此类功能。

Comments

这正是我所怀疑的。我觉得要再检查一下。有时我会看到一些地图处理的柔术，我学会了新技巧 :)

Answer 2

了解 `update-if-exists` 是好的，但它在这里并不会完全击中要害...

原始程序的主要和根本问题是它将每个键的逻辑和地图更新逻辑混淆在一起，从而掩盖了翻译的本质（例如，键和值都改变了）以及翻译之间的相互关系（后续的翻译是否依赖于早期的翻译）。

将两个关注点分开，每个都更容易改进。

要翻译1个属性，你可以有一个函数（可能是多方法），或一个查找表。例如，假设你有一个函数 svg->cljfx，它接受一个 [k v] (例如，一个映射条目)并生成一个新 [k v]；然后整个 svg-attributes 的翻译可以通过以下方式完成

(->> svg-attributes
     (map svg->cljfx)
     (into {}))

易读，但如果未更改的属性多于更改的属性，则不太CPU高效。

或者，假设你有一个svg键到函数（可能是匿名函数）的查找表，该函数生成了新的 [键 值] 对。循环可以遍历已知的转换。它将跳过缺失的键，但至少该情况可以一次性解决而不是每个键一次。逻辑会更复杂，但它可能运行得更快。

Comments

顺便说一句，你是使用 `edn/read-string` 吗？ 核心的 `read-string` 值得避免，除非你真想利用它的副作用。

---

哦，通过键值对映射真是巧妙！我完全忘了你还可以那样使用 `map`！感谢你的建议。虽然多方法将会有一点冗长，因为每个实例它只返回一个键。但无论如何，它比我现在用的方法要简洁。

Answer 3

如果所有默认值都是 "值"，并且函数处于尾位置，这将这样做

(defn set-defaults [v m f]
  (or (get m v) (f v)))

(defn points [s]
  (mapv read-string (clojure.string/split s #"[ ,]")))

(-> {:points    "1,2,3,4"
     :stroke    \#
     :font-size "none"}
  (update :stroke set-defaults {nil :black "none" :black \# \#} keyword)
  (update :fill set-defaults {nil "transparent" "none" "transparent" \# \#} keyword)
  (update :points set-defaults {nil [] [] []} points)
  (update :stroke-width set-defaults {nil 1.0} identity)
  (update :stroke-dasharray set-defaults {nil []} points)
  (update :font-size set-defaults {nil 10 "none" 10} identity)
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array}))

;=>
{:points            [1 2 3 4]
 :stroke            \#
 :font-size         10
 :fill              "transparent"
 :stroke-width      1.0
 :stroke-dash-array []}

否则，如果默认值中任意一个是函数

(defn set-defaults2 [v m defaultf]
  (let [f (get m v defaultf)]
    (f v)))

(-> {} 
  (update :stroke set-defaults2 {nil (constantly :black)}))

当然，在 `condp` 中有一个 `:>>` "特性"：https://docs.clojure.org/clojure.core/condp#example-542692cbc026201cdc326be4

Answer 4

如果你也更新与 nil 相等的现有值，那也没问题

(update your-map (fnil identity :default-value))