如何有条件地更新地图元素？

Question

我有代码正在将一种数据结构（SVG Hiccup 属性）转换为另一种格式（CLJFX 属性）。两种格式非常相似，但是当属性存在时，我有时需要对它进行调整。例如，可能需要将字符串（read-string ..）转换为数字，或者更新关键字以使其拼写略有不同等。

目前我的代码是这样的

(-> svg-attributes
  (update :stroke #(case %
                     nil :black
                     "none" :black
                     (if (= \# %)
                       %
                       (keyword %))))
  (update :fill #(case %
                   nil "transparent"
                   "none" "transparent"
                   (if (= \# %)
                     %
                     (keyword %))))
  (update :points #(case %
                     nil []
                     [] []
                     (map read-string (-> %
                                          (clojure.string/split #"[ ,]")))))
  (update :stroke-width #(case %
                           nil 1.0
                           %))
  (update :stroke-dasharray #(case %
                               nil []
                               (map read-string (-> %
                                                    (clojure.string/split #"[ ,]")))))
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array})
  (update :font-size #(case %
                        nil 10
                        "none" 10
                        %))))

问题是，我不得不捕获 nil 情况，并强行填充一些默认值……这大多数时间都奏效，但我更愿意在没有任何可更新内容时跳过更新。

我看到了这个问题，它与这个问题非常相似：https://ask.clojure.org/index.php/8387/how-to-avoid-nil-values-in-maps

使用 (cond-> 并在每个行上使用 (some? (:somekeyword %)) 是否是惯用的解决方案？我觉得我找错了工具！也许有人可以给我更好的建议：）

Answer 1

我在几个项目中看到了手写的 update-if-exists 变体，以下是在 medley util 库中的示例实现。

AFAIK，Clojure 核心中没有任何此类东西。

Comments

这正是我所怀疑的，我本想再次确认。有时我会看到一些地图处理的技巧，然后我能学到一招新技巧 :)

Answer 2

update-if-exists 是值得关注的知识点，但在这里并不能完全解决问题。

与原始程序相关的首要和根本的问题是，它将每个键的逻辑和地图更新逻辑纠缠在一起，从而模糊了翻译的性质（例如，键和值都发生改变）以及翻译之间的相互关系（后来翻译是否依赖于早期翻译）。

将两个问题分开，每个问题都更容易改进。

要翻译一个属性，你可以有一个函数（可能是多态的），或者一个查找表。例如，假设你有一个函数 svg->cljfx，它接收一个 [k v]（例如，一个映射条目）并生成一个新的 [k v]；然后可以通过以下方式翻译整个 svg-attributes

(->> svg-attributes
     (map svg->cljfx)
     (into {}))

易于阅读，但是如果未改变的属性数量多于已改变的属性，则CPU效率可能不是特别高。

或者，假设你已经有一个svg键到函数（可能是匿名的）的查找表，该函数生成一个新的 [key value] 对。循环可以迭代已知的转换。它必须跳过缺失的键，但是至少可以将这种情况一次性解决，而不是每个键单独解决。逻辑会更复杂，但可能运行得更快。

Comments

顺便说一句，你是在使用 `edn/read-string` 吗？ 核心中的 `read-string` 建议避免使用，除非你确实需要它的副作用。

---

哦，通过键值对进行映射真是聪明！我完全忘记了可以那样使用 `map`！感谢你的建议。我有点喜欢这个解决方案，尽管多方法将会有些冗长，因为它每次只返回一个键。尽管如此，它比我之前的方法更简洁。

Answer 3

如果所有默认值都是 "值"，并且函数处于尾位置，这将有效

(defn set-defaults [v m f]
  (or (get m v) (f v)))

(defn points [s]
  (mapv read-string (clojure.string/split s #"[ ,]")))

(-> {:points    "1,2,3,4"
     :stroke    \#
     :font-size "none"}
  (update :stroke set-defaults {nil :black "none" :black \# \#} keyword)
  (update :fill set-defaults {nil "transparent" "none" "transparent" \# \#} keyword)
  (update :points set-defaults {nil [] [] []} points)
  (update :stroke-width set-defaults {nil 1.0} identity)
  (update :stroke-dasharray set-defaults {nil []} points)
  (update :font-size set-defaults {nil 10 "none" 10} identity)
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array}))

;=>
{:points            [1 2 3 4]
 :stroke            \#
 :font-size         10
 :fill              "transparent"
 :stroke-width      1.0
 :stroke-dash-array []}

或者，如果默认值中任何一个可能也是一个函数

(defn set-defaults2 [v m defaultf]
  (let [f (get m v defaultf)]
    (f v)))

(-> {} 
  (update :stroke set-defaults2 {nil (constantly :black)}))

当然，`condp` 中有一个 `:>>` "功能"：https://docs.clojure.org/clojure.core/condp#example-542692cbc026201cdc326be4

Answer 4

如果你不介意更新等于 nil 的现有值

(update your-map (fnil identity :default-value))