如何有条件地更新地图元素？

Question

我有一些代码，将一种数据结构从一种格式转换为另一种格式（SVG hiccup 属性转换为 CLJFX 属性）。格式非常相似，但是当存在一个属性时，我偶尔需要对其进行一些修改。例如，可能需要将字符串（read-string ..）解析为数字，或者更新关键字，使其拼写略有不同，等等。

目前我的代码形式如下：

(-> svg-attributes
  (update :stroke #(case %
                     nil :black
                     "none" :black
                     (if (= \# %)
                       %
                       (keyword %))))
  (update :fill #(case %
                   nil "transparent"
                   "none" "transparent"
                   (if (= \# %)
                     %
                     (keyword %))))
  (update :points #(case %
                     nil []
                     [] []
                     (map read-string (-> %
                                          (clojure.string/split #"[ ,]")))))
  (update :stroke-width #(case %
                           nil 1.0
                           %))
  (update :stroke-dasharray #(case %
                               nil []
                               (map read-string (-> %
                                                    (clojure.string/split #"[ ,]")))))
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array})
  (update :font-size #(case %
                        nil 10
                        "none" 10
                        %))))

问题是我必须持续捕获 nil 的情况，并强行插入一些默认值……这在大多数情况下都有效，但我知道我还有更好的选择。

我看到了这个问题，它非常相似：https://ask.clojure.org/index.php/8387/how-to-avoid-nil-values-in-maps

在这种情况下，使用带有 (some? (:somekeyword %)) 的 (cond-> 是否是惯用的解决方案？我觉得我不是在寻找正确的工具！也许有人能给我更好的建议：）

Answer 1

我看到在几个项目中手动实现了 update-if-exists 的变体，以下是在 medley 工具库中的一个示例实现。

AFAIK，Clojure 核心中没有任何此类内容。

Comments

我就怀疑是这个。想再确认一下。有时我会看到一些地图处理技巧，可以学到新技巧 :)

Answer 2

了解 `update-if-exists` 是很好的，但在这里并不能击中要害..

原始方法的主要和根本的问题是，它将每个键的逻辑和更新映射逻辑混合在一起，从而掩盖了翻译的本质（例如，键和值都发生了变化）以及翻译之间的相互关系（后来的翻译是否依赖于早期的翻译）。

将两个问题分开，每个问题都会更容易改进。

要翻译1个属性，可以有一个函数（可能是一个多方法），或者查找表。例如，假设你有一个函数 svg->cljfx，它接受一个 [k v]（例如，映射条目）并生成一个新的 [k v]；那么可以通过下面方式翻译整个 svg-attributes：

(->> svg-attributes
     (map svg->cljfx)
     (into {}))

易于阅读，但如果不变的属性多于变化的属性，那么不太高效。

或者，假设你有一个将 svg 键映射到函数（可能是匿名函数）的查找表（映射），该函数产生一个新的 [key value] 对。循环可以遍历已知转换。它必须跳过缺失的键，但至少可以一次性覆盖这种情况，而不是每个键一次。逻辑会更复杂，但可能运行得更快。

Comments

顺便说一句，你真的在使用 `edn/read-string` 吗？ 核心中的 `read-string` 值得避免，除非你真的想要它的副作用。

---

哦，对键值对的映射很巧妙！我完全忘记了可以使用 `map` 这样操作！感谢你的建议。我有点喜欢这个解决方案，尽管多重方法将有点冗长，因为每个实例只返回一个键。尽管如此，它比我原来的方法更简洁。

Answer 3

如果默认值都是 "值"，并且函数处于尾递归位置，这样做就可以

(defn set-defaults [v m f]
  (or (get m v) (f v)))

(defn points [s]
  (mapv read-string (clojure.string/split s #"[ ,]")))

(-> {:points    "1,2,3,4"
     :stroke    \#
     :font-size "none"}
  (update :stroke set-defaults {nil :black "none" :black \# \#} keyword)
  (update :fill set-defaults {nil "transparent" "none" "transparent" \# \#} keyword)
  (update :points set-defaults {nil [] [] []} points)
  (update :stroke-width set-defaults {nil 1.0} identity)
  (update :stroke-dasharray set-defaults {nil []} points)
  (update :font-size set-defaults {nil 10 "none" 10} identity)
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array}))

;=>
{:points            [1 2 3 4]
 :stroke            \#
 :font-size         10
 :fill              "transparent"
 :stroke-width      1.0
 :stroke-dash-array []}

或者，如果任何默认值也可以是一个函数

(defn set-defaults2 [v m defaultf]
  (let [f (get m v defaultf)]
    (f v)))

(-> {} 
  (update :stroke set-defaults2 {nil (constantly :black)}))

当然，在 `condp` 中有一个 `:>> "功能"： https://docs.clojure.org/clojure.core/condp#example-542692cbc026201cdc326be4

Answer 4

如果你同意更新等于 `nil` 的现有值

(update your-map (fnil identity :default-value))