如何有条件地更新地图元素？

Question

我有一些代码，用于将一种数据结构转换为另一种格式（从SVG hiccup属性到CLJFX属性）。格式相当相似，但在属性存在时，我有时需要对其进行一些修改。例如，可能需要将字符串（read-string ..）读取为数字，或者更新一个关键字以使其拼写略有不同，等等。

目前我的代码形式如下

(-> svg-attributes
  (update :stroke #(case %
                     nil :black
                     "none" :black
                     (if (= \# %)
                       %
                       (keyword %))))
  (update :fill #(case %
                   nil "transparent"
                   "none" "transparent"
                   (if (= \# %)
                     %
                     (keyword %))))
  (update :points #(case %
                     nil []
                     [] []
                     (map read-string (-> %
                                          (clojure.string/split #"[ ,]")))))
  (update :stroke-width #(case %
                           nil 1.0
                           %))
  (update :stroke-dasharray #(case %
                               nil []
                               (map read-string (-> %
                                                    (clojure.string/split #"[ ,]")))))
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array})
  (update :font-size #(case %
                        nil 10
                        "none" 10
                        %))))

问题是我一直在捕获 nil 的情况，并强行添加一些默认值...这大多数时候是可行的...但我更愿意在没有要更新内容时跳过更新。

我看到了这个问题，与这个问题相当相似：https://ask.clojure.org/index.php/8387/how-to-avoid-nil-values-in-maps

在这个情况下，通过在每行应用 (cond-> 和 (some? (:somekeyword %)) 是否是惯用的解决方案？我觉得我并没找到合适的工具！也许有人可以给出更好的建议：）

Answer 1

我在几个项目中看到了手工编写的 update-if-exists 的变体，以下是在medley工具库中的一个示例实现。

AFAIK，在Clojure核心库中没有这样的东西。

Comments

这正是我所怀疑的。我想再确认一下。有时候，我看到一些地图操作的武术招式，我就学会了一个新技巧 :)

Answer 2

update-if-exists 是很重要的一个概念，但它在这里并不能完全解决问题。

原始程序的主要问题在于它将每次键的逻辑和更新地图的逻辑混在了一起，从而模糊了翻译的本质（例如，键和值都发生了变化）以及翻译之间的关系（后面的翻译是否依赖于前面的翻译）。

将这两个问题分开，每个问题都更容易解决。

为了翻译一个属性，你可以有一个函数（可能是多方法），或者一个查找表。例如，假设你有一个函数 svg->cljfx，它接受一个 [k v]（例如，一个映射条目）并生成一个新的 [k v]；然后可以按以下方式对整个 svg-attributes 进行翻译

(->> svg-attributes
     (map svg->cljfx)
     (into {}))

代码易于阅读，但在不变属性多于更改属性的情况下，CPU效率并不高。

或者，假设你有一个svg键到函数（可能是匿名函数）的查找表，该函数生成一个新的 [key value] 对。循环可以迭代已知的转换。它将跳过缺失的键，但至少可以一次性解决这种情况。逻辑会更复杂，但可能运行得更快。

Comments

附言：你使用的是 `edn/read-string` 吧？ core 中的 `read-string` 值得避免，除非你真的需要它的副作用。

---

哦，映射键值对非常巧妙！我完全忘记了你可以用 `map` 这样做！感谢你的建议。我有点喜欢这个解决方案，尽管多方法将会有点冗长，因为每次只返回一个键。不过，它比我原来的更简洁

Answer 3

如果所有默认值都是 "值"，并且函数在尾部位置，这样可以这样做

(defn set-defaults [v m f]
  (or (get m v) (f v)))

(defn points [s]
  (mapv read-string (clojure.string/split s #"[ ,]")))

(-> {:points    "1,2,3,4"
     :stroke    \#
     :font-size "none"}
  (update :stroke set-defaults {nil :black "none" :black \# \#} keyword)
  (update :fill set-defaults {nil "transparent" "none" "transparent" \# \#} keyword)
  (update :points set-defaults {nil [] [] []} points)
  (update :stroke-width set-defaults {nil 1.0} identity)
  (update :stroke-dasharray set-defaults {nil []} points)
  (update :font-size set-defaults {nil 10 "none" 10} identity)
  (clojure.set/rename-keys {:stroke-dasharray :stroke-dash-array}))

;=>
{:points            [1 2 3 4]
 :stroke            \#
 :font-size         10
 :fill              "transparent"
 :stroke-width      1.0
 :stroke-dash-array []}

或者，如果任何一个默认值也可以是一个函数的话

(defn set-defaults2 [v m defaultf]
  (let [f (get m v defaultf)]
    (f v)))

(-> {} 
  (update :stroke set-defaults2 {nil (constantly :black)}))

当然，`condp` 中有一个 `:>>` "功能"：[查看示例](https://docs.clojure.org/clojure.core/condp#example-542692cbc026201cdc326be4)

Answer 4

如果你也希望更新等于 nil 的现有值

(update your-map (fnil identity :default-value))