为什么 identical? 会将 let-bound 的 ##NaN 区分于它的直接引用？

Question

以下代码片段是用 Clojure 1.11.1 评估的

;; example 1
user=> (identical? Double/NaN Double/NaN)
false

;; example 2
user=> (let [x Double/NaN] (identical? x x))
false

;; example 3
user=> (identical? ##NaN ##NaN)
true

;; example 4
user=> (let [x ##NaN] (identical? x x))
false

为什么示例 3 返回 true，而所有其他示例都返回 false？这是预期的行为吗？

我认为这与 Clojure 有时使用的无包装数学有关。

在我的 Clojure 思维模型中，identical? 类似于 Java 的 == 操作符，而 ##NaN 是 Java 的 Double.NaN。在 Java 中，Double.NaN == Double.NaN 评估为 false。因此我期望所有示例都返回 false。

Answer 1

好吧，我对 identical? 的思维模型不准确。它调用了 clojure.lang.Util/identical，其实现如下

static public boolean identical(Object k1, Object k2){
    return k1 == k2;
}

当 Clojure 以此签名调用函数时，它必须在参数中对原始值进行包装。它们通过调用 Double.valueOf(double) 对 Double 进行包装。NaN 的非寻常的等价语义使得示例变得复杂，但在所有情况下，identical? 比较的是已包装值的引用等价性，而不是数值等价性。

通过查看反汇编的字节码（见下文），我们可以看到发生了什么。以下为摘要。

• 在示例 1、2 和 4 中，每个传递给 identical? 的参数都是单独进行包装的。
• 在示例 3 中，##NaN 仅被包装一次，并且相同的已包装值被用作 identical? 的两个参数。

这里有一些更多示例。请注意，##Inf的行为与##NaN的行为相匹配。

(identical? ##Inf ##Inf)          ; true
(let [x ##Inf] (identical? x x))  ; false

(identical? 1.0 1.0)              ; false
(let [x 1.0] (identical? x x))    ; false

(def my-one 1.0)
(identical? my-one my-one)        ; true

结论

一切如预期所示。我对identical?的心理模型是错误的。它更像是(Object)... == (Object) ...而不是普通的==。

经验教训：仅使用identical?进行引用相等性比较。

拆解示例

代码已使用clj-java-decompiler拆解。

示例 1 (identical? Double/NaN Double/NaN)

class user$fn_line_1__254
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       java/lang/Double.NaN:D
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
               6: getstatic       java/lang/Double.NaN:D
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 18 42 07 00 1D
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__254.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

示例 2 (let [x Double/NaN] (identical? x x))

跳过；与示例 4 类似。

示例 3 (identical? ##NaN ##NaN)

请注意，装箱是在静态块中发生的。

class user$fn_line_1__246
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public static final java.lang.Object const__1;
        Flags: PUBLIC, STATIC, FINAL
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               3: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
                  linenumber      1
               6: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
               9: ifeq            18
              12: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              15: goto            21
              18: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              21: areturn        
        StackMapTable: 00 02 12 42 07 00 17
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__246.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               6: putstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               9: return         

示例 4 (let [x ##NaN] (identical? x x))

注意invokeStatic方法中的两个Double.valueOf调用。

class user$fn_line_1__250
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: dstore_0        /* x */
               4: dload_0         /* x */
               5: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               8: dload_0         /* x */
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 FC 00 18 03 42 07 00 1B
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__250.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

Comments

有趣。我对`identical?`的心理模型是准确的（`identical?`对所有相同的对象返回true），但我对Clojure的参数传递的心理模型有缺陷。看看你的示例，我认为以下是这样发生的。

```clojure
;; 示例 1
user=> (identical? Double/NaN Double/NaN)
false
;; 很可能是正确的。如果Double/NaN被标记为final，那么应该是true，但它显然不是，尽管Double类被标记为final。

;; 示例 2
user=> (let [x Double/NaN] (identical? x x))
false
;; 我认为Clojure编译器应该仅装箱一次，并将相同的boxed值传递给identical?，从而为true

;; 示例 3
user=> (identical? ##NaN ##NaN)
true
;; 我很高兴这是真的，但对这种优化作为一个特殊案例表示惊讶。

;; 示例 4
user=> (let [x ##NaN] (identical? x x))
false
;; 与示例 2 类似，Clojure编译器应该足够智能，仅装箱一次，从而为true。
```

基本上，我的直觉是，如果`x`被绑定到一个值，那么这个相同的对象（无论是boxed还是unboxed），都应该传递给被调用的函数。纯粹从效率的角度来看，这与`identical?`无关，编译器不应该多次对相同的原始值装箱。因此，我认为这看起来像是一个Clojure编译器没有生成直观或最佳代码的问题。

Answer 2

在示例 3 中，reader将这些常数绑定到相同的Object常数下，因此只有一个类型为Object的实例。

在其他例子中，存在double类型的实例。

总之，这正是Java的工作方式：[链接](https://stackoverflow.com/a/1408643/564509)

这是一个演示Java行为的简单方法

jshell> Object a = Double.NaN
a ==> NaN

jshell> a == a
$2 ==> true

jshell> double a = Double.NaN
a ==> NaN

jshell> a == a
$4 ==> false

Comments

你是如何得出这个结论的？

---

如果你指的是我消息中的前两个陈述，那么我得到了你的Clojure代码，编译它，反编译它，并检查了结果。

---

你是否使用了clj-java-decompiler的反编译功能（Java输出）？也尝试使用disassemble（字节码输出）；它并不真的很符合你的解释。

---

我使用的是内置在IntelliJ IDEA中的反编译器。但是，你使用什么并不重要。最后，你甚至可以用一些查看器检查字节码。为了增加确定性，你可以使用`def`将你的OP中的每个表达式绑定到一个名称。