为什么 identical? 会将 let 绑定的 ##NaN 与直接引用它的方式处理得不同？

Question

以下代码片段是用 Clojure 1.11.1 运行的

;; example 1
user=> (identical? Double/NaN Double/NaN)
false

;; example 2
user=> (let [x Double/NaN] (identical? x x))
false

;; example 3
user=> (identical? ##NaN ##NaN)
true

;; example 4
user=> (let [x ##NaN] (identical? x x))
false

为什么示例 3 返回 true，而所有其他示例都返回 false？这是预期的行为吗？

我认为这与 Clojure 有时使用的无包装数学有关。

在我的 Clojure 心理模型中，identical? 实际上是 Java 的 ==，而 ##NaN 是 Java 的 Double.NaN。在 Java 中，Double.NaN == Double.NaN 评估为 false。因此，我预计所有示例都会返回 false。

Answer 1

好吧，我对 identical? 的心理模型不准确。它调用 clojure.lang.Util/identical，其实现如下

static public boolean identical(Object k1, Object k2){
    return k1 == k2;
}

当 Clojure 调用一个这样的函数时，它必须对参数中的原始值进行装箱。使用 Double.valueOf(double) 对双精度浮点数进行装箱。NaN 的不寻常的等价语义使示例令人困惑，但在每种情况下，identical? 比较装箱值的引用等价性，而不是数值等价性。

通过查看反汇编的字节码（见下文），我们可以看到发生了什么。以下是总结。

• 在示例 1、2 和 4 中，每个 identical? 的参数都单独装箱。
• 在示例 3 中，##NaN 仅装箱一次，并且相同的装箱值用作 identical? 的两个参数。

这里还有一些其他示例。注意，##Inf 的行为与 ##NaN 相似。

(identical? ##Inf ##Inf)          ; true
(let [x ##Inf] (identical? x x))  ; false

(identical? 1.0 1.0)              ; false
(let [x 1.0] (identical? x x))    ; false

(def my-one 1.0)
(identical? my-one my-one)        ; true

结论

一切按预期运行。我对identical?的心理模型是错误的。它更像是(Object)... == (Object) ...而不是普通的==。

教训：仅使用identical?检查引用等价性。

反汇编示例

代码已经使用clj-java-decompiler进行反汇编。

示例 1 (identical? Double/NaN Double/NaN)

class user$fn_line_1__254
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       java/lang/Double.NaN:D
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
               6: getstatic       java/lang/Double.NaN:D
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 18 42 07 00 1D
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__254.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

示例 2 (let [x Double/NaN] (identical? x x))

跳过；与示例 4 类似。

示例 3 (identical? ##NaN ##NaN)

注意装箱发生在了静态块中。

class user$fn_line_1__246
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public static final java.lang.Object const__1;
        Flags: PUBLIC, STATIC, FINAL
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               3: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
                  linenumber      1
               6: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
               9: ifeq            18
              12: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              15: goto            21
              18: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              21: areturn        
        StackMapTable: 00 02 12 42 07 00 17
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__246.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               6: putstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               9: return         

示例 4 (let [x ##NaN] (identical? x x))

在invokeStatic方法中注意到两个Double.valueOf调用。

class user$fn_line_1__250
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: dstore_0        /* x */
               4: dload_0         /* x */
               5: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               8: dload_0         /* x */
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 FC 00 18 03 42 07 00 1B
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__250.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

Comments

很有趣。我的`identical?`心理模型正确（`identical?`对相同对象返回true），但我的Clojure参数传递心理模型有误。根据你的例子，我认为应该这样发生。

```clojure
;; 示例 1
user=> (identical? Double/NaN Double/NaN)
false
;; 很可能是正确的。如果 Double/NaN 被标记为 final，那么应该为 true，但它显然没有被标记为 final，尽管 Double 类被标记为 final。

;; 示例 2
user=> (let [x Double/NaN] (identical? x x))
false
;; 我认为 Clojure 编译器应该装箱一次并将相同的盒子传递给 identical?，因此是 true

;; 示例 3
user=> (identical? ##NaN ##NaN)
true
;; 我很高兴这是正确的，但对此作为特殊情况进行了优化感到惊讶。

;; 示例 4
user=> (let [x ##NaN] (identical? x x))
false
;; 与示例 2 类似，Clojure 编译器应该足够智能，只对其进行一次装箱，因此是 true。
```

基本上，我的直觉是如果 `x` 被让绑定在一个值上，那么无论是装箱还是解装箱的相同对象，都应该传递给被调用的函数。仅从效率的角度来看，这与 `identical?` 无关，编译器不应对同一原始值进行多次装箱。所以，我认为这似乎是一个 Clojure 编译器生成既不直观也不是最优代码的问题。

Answer 2

示例 3 中，读取器将这两个常量绑定到同一个 Object 常量下，所以只有一个类型为 Object 的实例。

在其他示例中，存在了类型为 double 的实例。

鉴于此，这正是 Java 的工作方式：https://stackoverflow.com/a/1408643/564509

演示 Java 行为的简单方法

jshell> Object a = Double.NaN
a ==> NaN

jshell> a == a
$2 ==> true

jshell> double a = Double.NaN
a ==> NaN

jshell> a == a
$4 ==> false

Comments

你是如何得出这个结论的？

---

如果你指的是我信息中的前两个陈述，那么我获取了你的 Clojure 代码，编译并反编译它，并检查了结果。

---

你使用的是 clj-java-decompiler 的反编译（Java 输出）吗？也尝试使用 disassemble（字节码输出）；它并不完全符合你的解释。

---

我使用了 IntelliJ IDEA 内置的反编译器。但使用什么并不会那么重要。最后，你甚至可以用一些查看器检查字节码。为了提高确定性，你可以用 `def` 将你的 OP 中的每个表达式绑定到一个名称上。