为什么identical?对let-bound的##NaN的处理与直接引用它不同？

Question

考虑以下代码片段在Clojure 1.11.1中的评估结果。

;; example 1
user=> (identical? Double/NaN Double/NaN)
false

;; example 2
user=> (let [x Double/NaN] (identical? x x))
false

;; example 3
user=> (identical? ##NaN ##NaN)
true

;; example 4
user=> (let [x ##NaN] (identical? x x))
false

为什么示例3返回true而其他所有示例都返回false？这是预期的行为吗？

我认为这与Clojure有时使用无包装数值的方式有关。

在我的Clojure心理模型中，identical?基本上相当于Java的==，而##NaN是Java的Double.NaN。在Java中，Double.NaN == Double.NaN求值为false。因此，我预计所有示例都会返回false。

Answer 1

好吧，我对identical?的心理模型不准确。它调用clojure.lang.Util/identical，其实现如下

static public boolean identical(Object k1, Object k2){
    return k1 == k2;
}

当Clojure调用具有此签名的函数时，它必须对参数中的原始值进行装箱。通过调用Double.valueOf(double)对Double进行装箱。NaN的不寻常等价性语义使示例变得混乱，但在每种情况下，identical?比较装箱值的引用等价性，而不是数值等价性。

通过查看反汇编后的字节码（见下文），我们可以看到发生了什么。以下是总结。

• 在示例1、2和4中，每个传递给identical?的参数都单独装箱。
• 在示例3中，##NaN仅装箱一次，并使用相同的装箱值作为identical?的两个参数。

这里有一些更多示例。请注意，##Inf 的行为与 ##NaN 一致。

(identical? ##Inf ##Inf)          ; true
(let [x ##Inf] (identical? x x))  ; false

(identical? 1.0 1.0)              ; false
(let [x 1.0] (identical? x x))    ; false

(def my-one 1.0)
(identical? my-one my-one)        ; true

结论

一切工作如预期。我对 identical? 的理解是错误的。它更像是 (Object)... == (Object) ... 而不是简单的 ==。

经验教训：仅使用 identical? 进行引用等价性比较。

拆解示例

代码已经使用 clj-java-decompiler 进行拆解。

示例 1 (identical? Double/NaN Double/NaN)

class user$fn_line_1__254
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       java/lang/Double.NaN:D
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
               6: getstatic       java/lang/Double.NaN:D
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 18 42 07 00 1D
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__254.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

示例 2 (let [x Double/NaN] (identical? x x))

省略；与示例 4 类似。

示例 3 (identical? ##NaN ##NaN)

请注意装箱发生在静态块中。

class user$fn_line_1__246
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public static final java.lang.Object const__1;
        Flags: PUBLIC, STATIC, FINAL
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               3: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
                  linenumber      1
               6: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
               9: ifeq            18
              12: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              15: goto            21
              18: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              21: areturn        
        StackMapTable: 00 02 12 42 07 00 17
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__246.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               6: putstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               9: return         

示例 4 (let [x ##NaN] (identical? x x))

注意 invokeStatic 方法中的两个 Double.valueOf 调用。

class user$fn_line_1__250
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: dstore_0        /* x */
               4: dload_0         /* x */
               5: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               8: dload_0         /* x */
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 FC 00 18 03 42 07 00 1B
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__250.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

Comments

很有趣。我对 `identical?` 的理解是准确的（`identical?` 对同类对象返回 true），但对我对 Clojure 参数传递的理解是错误的。根据您的示例，以下是我认为应该发生的情况。

```clojure
;; 示例 1
user=> (identical? Double/NaN Double/NaN)
false
;; 可能是正确的。如果 Double/NaN 被标为 final，则应该是 true，但显然不是，尽管 Double 类被标记为 final。

;; 示例 2
user=> (let [x Double/NaN] (identical? x x))
false
;; 我认为 Clojure 编译器应该仅装箱一次并将同一个缓冲传递给 identical?，因此 true

;; 示例 3
user=> (identical? ##NaN ##NaN)
true
;; 我很高兴这是真的，但很惊讶这个被优化为特殊情况。

;; 示例 4
user=> (let [x ##NaN] (identical? x x))
false
;; 与示例 2 类似，Clojure 编译器应该足够聪明，只装箱一次，因此 true。
```

基本上，我的直觉是如果 `x` 被绑定到一个值，那么相同的对象（无论装箱还是未装箱），都应该传递给一个调用函数。纯粹以效率而言，这与 `identical?` 没有关，编译器不应该多次对同一个原始值进行装箱。因此，我认为这可能是 Clojure 编译器不生成直观或最优代码的问题。

Answer 2

在示例3中，读者将那两个常量绑定到同一个Object常量下，所以只有一个类型为Object的实例。

在其他示例中，存在类型为double的实例。

所有这些，都是Java的工作方式：[链接](https://stackoverflow.com/a/1408643/564509)

演示Java行为的一个简单方法

jshell> Object a = Double.NaN
a ==> NaN

jshell> a == a
$2 ==> true

jshell> double a = Double.NaN
a ==> NaN

jshell> a == a
$4 ==> false

Comments

你是怎么得出这个结论的？

---

如果你的意思是我的信息中的前两个陈述，那么我得到了你的Clojure代码，编译它，反编译，并检查结果。

---

你使用clj-java-decompiler的反编译功能了吗？也可以尝试使用disassemble（字节码输出），这并不完全符合你的解释。

---

我使用了集成在IntelliJ IDEA中的反编译器。但这并不重要。最后，你甚至可以使用一些查看器来检查字节码。为了提高确定性，你可以使用`def`s将你的OP中的每个表达式绑定到一个名字。