为什么相似? 用法将类似的NaN处理得和它直接引用的方式不同？

Question

考虑以下代码片段用Clojure 1.11.1进行评估

;; example 1
user=> (identical? Double/NaN Double/NaN)
false

;; example 2
user=> (let [x Double/NaN] (identical? x x))
false

;; example 3
user=> (identical? ##NaN ##NaN)
true

;; example 4
user=> (let [x ##NaN] (identical? x x))
false

为什么示例3返回true，其他所有示例都返回false？这是预期的行为吗？

我认为这与Clojure有时使用无包数学有关。

在我的Clojure心智模型中，identical?基本上是Java的==，而##NaN是Java的Double.NaN。在Java中，Double.NaN == Double.NaN的评估结果为false。因此，我预期所有示例都返回false。

Answer 1

好吧，我的identical?心智模型不准确。它调用clojure.lang.Util/identical，其实现如下

static public boolean identical(Object k1, Object k2){
    return k1 == k2;
}

当Clojure用这种签名调用函数时，它必须将参数中的原始值装箱。double通过调用Double.valueOf(double)装箱。NaN的特殊等价语义使得示例令人困惑，但在每一种情况下，identical?都比较装箱值的引用等价性，而不是数值等价性。

通过查看反汇编的字节码（见下文），我们可以看到发生了什么。这里是总结。

• 在示例1、2和4中，每个传递给identical?的参数都单独装箱。
• 在示例3中，##NaN仅装箱一次，相同的装箱值用于identical?的两个参数。

这里有更多示例。注意，##Inf的行为与##NaN的行为一致。

(identical? ##Inf ##Inf)          ; true
(let [x ##Inf] (identical? x x))  ; false

(identical? 1.0 1.0)              ; false
(let [x 1.0] (identical? x x))    ; false

(def my-one 1.0)
(identical? my-one my-one)        ; true

结论

一切如预期工作。我对 identical? 的理解是错误的。它更像 (Object)... == (Object) ... 而非简单的 ==。

经验教训：只使用 identical? 检查引用相等。

反汇编示例

代码已被使用 clj-java-decompiler 反汇编。

示例 1 (identical? Double/NaN Double/NaN)

class user$fn_line_1__254
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       java/lang/Double.NaN:D
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
               6: getstatic       java/lang/Double.NaN:D
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 18 42 07 00 1D
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__254.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

示例 2 (let [x Double/NaN] (identical? x x))

省略；与示例 4 类似。

示例 3 (identical? ##NaN ##NaN)

注意装箱操作发生在静态块中。

class user$fn_line_1__246
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public static final java.lang.Object const__1;
        Flags: PUBLIC, STATIC, FINAL
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               3: getstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
                  linenumber      1
               6: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
               9: ifeq            18
              12: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              15: goto            21
              18: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              21: areturn        
        StackMapTable: 00 02 12 42 07 00 17
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__246.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               6: putstatic       user$fn_line_1__246.const__1:Ljava/lang/Object;
               9: return         

示例 4 (let [x ##NaN] (identical? x x))

注意 invokeStatic 方法中有两个 Double.valueOf 调用。

class user$fn_line_1__250
    Minor version: 0
    Major version: 52
    Flags: PUBLIC, FINAL, SUPER
    
    public void <init>();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: aload_0        
               1: invokespecial   clojure/lang/AFunction.<init>:()V
               4: return         
    
    public static java.lang.Object invokeStatic();
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: ldc2_w          NaN
               3: dstore_0        /* x */
               4: dload_0         /* x */
               5: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
               8: dload_0         /* x */
               9: invokestatic    java/lang/Double.valueOf:(D)Ljava/lang/Double;
                  linenumber      1
              12: invokestatic    clojure/lang/Util.identical:(Ljava/lang/Object;Ljava/lang/Object;)Z
              15: ifeq            24
              18: getstatic       java/lang/Boolean.TRUE:Ljava/lang/Boolean;
              21: goto            27
              24: getstatic       java/lang/Boolean.FALSE:Ljava/lang/Boolean;
              27: areturn        
        StackMapTable: 00 02 FC 00 18 03 42 07 00 1B
    
    public java.lang.Object invoke();
        Flags: PUBLIC
        Code:
                  linenumber      1
               0: invokestatic    user$fn_line_1__250.invokeStatic:()Ljava/lang/Object;
               3: areturn        
    
    static {};
        Flags: PUBLIC, STATIC
        Code:
                  linenumber      1
               0: return         

Comments

有趣。我关于 `identical?` 的理解是准确的 (`identical?` 对于相同的对象返回 true)，但关于 Clojure 的参数传递的想法是错误的。根据你的示例，以下是我认为应该发生的情况。

```clojure
;; 示例 1
user=> (identical? Double/NaN Double/NaN)
false
;; false 可能是正确的。如果 Double/NaN 被标记为 final，那么应该是 true，但显然不是，尽管 Double 类被标记为 final。

;; 示例 2
user=> (let [x Double/NaN] (identical? x x))
false
;; 我认为 Clojure 编译器应该只装箱一次，然后传递相同的 box 给 identical?，从而得到 true

;; 示例 3
user=> (identical? ##NaN ##NaN)
true
;; 我很高兴这是正确的，但对此作为一个特殊情况进行了优化感到惊讶。

;; 示例 4
user=> (let [x ##NaN] (identical? x x))
false
;; 与示例 2 类似，Clojure 编译器应该足够智能，只对这个值装箱一次，从而得到 true。
```

总之，我认为如果 `x` 被绑定到一个值，这个相同对象，无论装箱还是未装箱，都应传递给调用函数。这纯粹是效率问题，和 `identical?` 无关，编译器不应重复装箱相同的原始值。所以我认为，这似乎是 Clojure 编译器没有生成直观或最优代码的问题。

Answer 2

示例 3 中，reader 会将这些两个常量绑定到同一 Object 常量下，因此只有一个 Object 类型的实例。

在其他示例中，存在 double 类型的实例。

具备所有这些，这正是Java的工作方式： https://stackoverflow.com/a/1408643/564509

演示Java行为的简单方法

jshell> Object a = Double.NaN
a ==> NaN

jshell> a == a
$2 ==> true

jshell> double a = Double.NaN
a ==> NaN

jshell> a == a
$4 ==> false

Comments

你是如何得出这个结论的？

---

如果你指的是我信息中的前两个声明，那么我已经收到了你的Clojure代码，编译、反编译并检查了结果。

---

你是否使用了clj-java-decompiler的反编译（Java输出）？也尝试使用disassemble（字节码输出）吧；它并不真正符合你的解释。

---

我使用了内置在IntelliJ IDEA中的反编译器。但这并不真正重要你使用什么。最终，你甚至可以使用一些查看器来检查字节码。为了增加确定性，你可以使用 `def` 将你的OP中的每个表达式绑定到一个名称。