映射解构的Rest

Question

我建议为映射解构语法添加:rest键。
您认为这个特性有什么用？

(let [m {:a 1 :b 2}
      {:keys [a] :rest r} m]
  (assert (= {:b 2} r)))
      

甚至像数组的其余部分[a b & r]

(let [m {:a 1 :b 2}
      {:keys [a]
       :& r} m]
  (assert (= {:b 2} r)))

Answer 1

这通常没有意义，因为映射是无序的（默认情况下），并且以此方式解构无法保证会首先得到<[:a 1]>键值对。

不过，现在您可以将映射视为键值对的一个序列（要注意顺序是任意的），然后对第一个键值对使用关联解构

(let [m {:a 1 :b 2}
      [[& {:keys [a b]}] & r] m]
  (println a b r))
;; 1 nil ([:b 2])

但为了重申，这里没有保证首先是看到[:a 1]，您也可能得到[:b 2]。

Comments

你没有正确理解我。
我写下 `[a b & r]` 只是为了建议使用 `:&` 关键字而不是 `:rest`。

这个问题是关于如何获取一个不包含选择键的映射。
映射的顺序并不重要。

请看下面的例子：(assert (= {:b 2} r))。它使用的是花括号而不是括号。

---

好的，我认为我们不会这么做。

---

出于好奇，不知道为什么不能这么做？我遇到过一些地方，如果不重复相同的键，使用这个可能更方便，稍后不需要进行 disoc 操作。

Answer 2

如果你想自己实现，你可以在自己的库中使用宏来扩展语言。这是一种有限的方式，虽然它不会递归遍历形式和完全替换 let；如果你想启用 :rest 表单，你必须用它来代替 let。有一些方法可以代码遍历和利用宏工具（如 macrolet 及其他工具）来实现，但这是读者练习的一部分。质量保证通知我说，他们没有时间在外部测试，所以他们提醒用户注意。

(defmacro fancy-let [bindings & body]
  (let [binds (partition-all 2 bindings)
        _     (assert (every? #(= 2 (count %)) binds) "binding form must be even yo!")]
    `(let [~@(->> (for [[l r :as b] binds]
                    (if (and (map? l)
                             (l :rest)
                             (or (l :keys) (l :syms) (l :strs)))
                      (let [ks        (l :keys)
                            strs      (l :strs)
                            syms      (l :syms)
                            remaining (l :rest)
                            selected  (concat (map keyword ks)
                                              (map name strs)
                                              (for [s syms]
                                                `(quote ~s)))
                            symb      (gensym "the-map")]
                        [symb r
                         (dissoc l :rest)  symb
                         remaining        `(dissoc ~symb ~@selected)])
                      b))
                  (reduce (fn [acc xs] (apply conj acc xs)) []))]
       ~@body)))

user> (fancy-let [{:keys [a] :strs [name age] :syms [origin] :rest m}
                 {:a 1 :b 2 :c 3 "name" "bilbo" "age" 200 'origin :shire}]
                 {:a a :name name :age age :origin origin :remaining m})
{:a 1, :name "bilbo", :age 200, :origin :shire, :remaining {:b 2, :c 3}}