map解构的休止符

Question

我建议添加:rest键以用于map解构语法。
您认为这个特性会如何有用？

(let [m {:a 1 :b 2}
      {:keys [a] :rest r} m]
  (assert (= {:b 2} r)))
      

或者，就像数组的余下部分一样 [a b & r]

(let [m {:a 1 :b 2}
      {:keys [a]
       :& r} m]
  (assert (= {:b 2} r)))

Answer 1

这通常没有意义，因为映射是无序的（默认情况），并且以这种方式解构不会有任何保证您会首先看到<[:a 1]>这样的键值对。

但是，现在您可以将映射视为键值对序列（但要注意，顺序是随机的），然后对第一个键值对使用关联解构

(let [m {:a 1 :b 2}
      [[& {:keys [a b]}] & r] m]
  (println a b r))
;; 1 nil ([:b 2])

但为了重申，这里没有保证首先看到[:a 1]，您也可能看到[:b 2]。

Comments

你没有正确理解我。
我写下 `[a b & r]` 仅是为了建议使用 `:&` 关键字来代替 `:rest`。

问题是关于获取一个没有选择键的地图。
并且映射的顺序不重要。

请看这个例子：(assert (= {:b 2} r))。它使用的是花括号而不是方括号。

---

好吧，我想我们不会这么做。

---

只是出于好奇，为什么不能这样做？我遇到一些地方，如果不需要稍后解耦合，可以使用这种方法来重复相同的键。

Answer 2

如果您想自己实现，您可以使用宏来扩展您自己的库中的语言。这是一个有限的办法，虽然它不会递归地遍历表单并完全替换 `let`；如果您想启用 :rest 表单，就必须替换它。有使用宏工具（如 macrolet 和其他工具）进行代码遍历和扩展的方法，但这是读者的练习。质量保证通知我，他们没有时间在其他即时 repl 输出之外测试这个，所以用户请小心。

(defmacro fancy-let [bindings & body]
  (let [binds (partition-all 2 bindings)
        _     (assert (every? #(= 2 (count %)) binds) "binding form must be even yo!")]
    `(let [~@(->> (for [[l r :as b] binds]
                    (if (and (map? l)
                             (l :rest)
                             (or (l :keys) (l :syms) (l :strs)))
                      (let [ks        (l :keys)
                            strs      (l :strs)
                            syms      (l :syms)
                            remaining (l :rest)
                            selected  (concat (map keyword ks)
                                              (map name strs)
                                              (for [s syms]
                                                `(quote ~s)))
                            symb      (gensym "the-map")]
                        [symb r
                         (dissoc l :rest)  symb
                         remaining        `(dissoc ~symb ~@selected)])
                      b))
                  (reduce (fn [acc xs] (apply conj acc xs)) []))]
       ~@body)))

user> (fancy-let [{:keys [a] :strs [name age] :syms [origin] :rest m}
                 {:a 1 :b 2 :c 3 "name" "bilbo" "age" 200 'origin :shire}]
                 {:a a :name name :age age :origin origin :remaining m})
{:a 1, :name "bilbo", :age 200, :origin :shire, :remaining {:b 2, :c 3}}