Map 解构的休息

Question

我建议在解构语法中添加 :rest 键。
您认为这个特性会有哪些用途？

(let [m {:a 1 :b 2}
      {:keys [a] :rest r} m]
  (assert (= {:b 2} r)))
      

或者就像是数组的剩余部分 [a b & r]

(let [m {:a 1 :b 2}
      {:keys [a]
       :& r} m]
  (assert (= {:b 2} r)))

Answer 1

这通常没有意义，因为映射是无序的（默认情况），以这种方式解构不会保证首先看到 [:a 1] 键值对。

但是，现在您可以将映射视为键值对序列（注意顺序是任意的），然后对第一个键值对使用关联解构。

(let [m {:a 1 :b 2}
      [[& {:keys [a b]}] & r] m]
  (println a b r))
;; 1 nil ([:b 2])

但重申一下，这里没有保证 [:a 1] 会首先被看到，您也可能看到 [:b 2]。

Comments

你没有正确理解我。
我写下 `[a b & r]` 只是为了建议使用 `:&` 关键字而不是 `:rest`。

这个问题是关于如何获取不包含选择键的映射。
而且映射的顺序并不重要。

请看以下示例：`(assert (= {:b 2} r))`。它使用圆括号而不是方括号。

---

好吧，我不认为我们会这么做。

---

只是出于好奇，有没有什么原因不使用它呢？我曾经遇到过一些地方，在这些地方不使用它会更方便，不必之后重复相同的键进行解构。

Answer 2

如果您想自己实现，您可以使用宏来扩展自己的库中的语言。这是一个有限的方法，虽然它不会递归地遍历形式并完全替换 let；如果您想启用 :rest 结构，则必须将其用作 let 的替代品。有使用宏工具（如 macrolet 和其他工具）进行代码遍历和扩展的方法，但这些都是留给读者的练习。质量保证团队通知我说，他们没有时间在您看到的即时 repl 输出之外进行测试，所以请用户小心。

(defmacro fancy-let [bindings & body]
  (let [binds (partition-all 2 bindings)
        _     (assert (every? #(= 2 (count %)) binds) "binding form must be even yo!")]
    `(let [~@(->> (for [[l r :as b] binds]
                    (if (and (map? l)
                             (l :rest)
                             (or (l :keys) (l :syms) (l :strs)))
                      (let [ks        (l :keys)
                            strs      (l :strs)
                            syms      (l :syms)
                            remaining (l :rest)
                            selected  (concat (map keyword ks)
                                              (map name strs)
                                              (for [s syms]
                                                `(quote ~s)))
                            symb      (gensym "the-map")]
                        [symb r
                         (dissoc l :rest)  symb
                         remaining        `(dissoc ~symb ~@selected)])
                      b))
                  (reduce (fn [acc xs] (apply conj acc xs)) []))]
       ~@body)))

user> (fancy-let [{:keys [a] :strs [name age] :syms [origin] :rest m}
                 {:a 1 :b 2 :c 3 "name" "bilbo" "age" 200 'origin :shire}]
                 {:a a :name name :age age :origin origin :remaining m})
{:a 1, :name "bilbo", :age 200, :origin :shire, :remaining {:b 2, :c 3}}