map解构的剩余部分

Question

建议为map解构语法添加:rest键。
您认为这个特性会有什么用呢？

(let [m {:a 1 :b 2}
      {:keys [a] :rest r} m]
  (assert (= {:b 2} r)))
      

甚至如数组的剩余部分 [a b & r]

(let [m {:a 1 :b 2}
      {:keys [a]
       :& r} m]
  (assert (= {:b 2} r)))

Answer 1

这通常没有意义，因为map是无序的（默认情况下），并以这种方式解构不会保证首先得到[:a 1] kv对。

尽管如此，您现在可以使用顺序解构，如果将map视为kv对的序列（注意顺序是任意的），然后对第一个kv对使用关联解构。

(let [m {:a 1 :b 2}
      [[& {:keys [a b]}] & r] m]
  (println a b r))
;; 1 nil ([:b 2])

但再次强调，在这里没有保证首先看到[:a 1]；您也可能得到[:b 2]。

Comments

你没有正确理解我。
我写下 `[a b & r]` 只是为了建议使用 `:&` 关键字而不是 `:rest`。

问题是关于获取一个没有选中键的地图。
且地图排序不重要。

请看示例：(assert (= {:b 2} r))`。它使用的是花括号而不是方括号。

---

好，我不认为我们会这样做。

---

出于好奇，为什么不可以呢？我遇到过这种情况，如果不想在后面反复使用相同的键来去除连字符，这可能会很方便。

Answer 2

如果您想自行操作，可以使用宏来扩展您自己的库中的语言。这是一种有限的途径，尽管它不会递归地遍历形式和完全替换 let；如果您想启用 :rest 格式，就必须用它代替 let。有使用宏工具（如 macrolet 和其他工具）进行代码遍历和扩展的方法，但这需要读者自行实践。质量保证告诉我，他们没有时间在所看到的直接 repl 输出之外进行测试，所以用户请注意。

(defmacro fancy-let [bindings & body]
  (let [binds (partition-all 2 bindings)
        _     (assert (every? #(= 2 (count %)) binds) "binding form must be even yo!")]
    `(let [~@(->> (for [[l r :as b] binds]
                    (if (and (map? l)
                             (l :rest)
                             (or (l :keys) (l :syms) (l :strs)))
                      (let [ks        (l :keys)
                            strs      (l :strs)
                            syms      (l :syms)
                            remaining (l :rest)
                            selected  (concat (map keyword ks)
                                              (map name strs)
                                              (for [s syms]
                                                `(quote ~s)))
                            symb      (gensym "the-map")]
                        [symb r
                         (dissoc l :rest)  symb
                         remaining        `(dissoc ~symb ~@selected)])
                      b))
                  (reduce (fn [acc xs] (apply conj acc xs)) []))]
       ~@body)))

user> (fancy-let [{:keys [a] :strs [name age] :syms [origin] :rest m}
                 {:a 1 :b 2 :c 3 "name" "bilbo" "age" 200 'origin :shire}]
                 {:a a :name name :age age :origin origin :remaining m})
{:a 1, :name "bilbo", :age 200, :origin :shire, :remaining {:b 2, :c 3}}