映射解构的`rest`关键字

Question

我建议为映射解构语法添加`:rest`键。
你认为这个特性会如何有用？

(let [m {:a 1 :b 2}
      {:keys [a] :rest r} m]
  (assert (= {:b 2} r)))
      

或者甚至像数组中的`[a b & r]`的“rest”部分

(let [m {:a 1 :b 2}
      {:keys [a]
       :& r} m]
  (assert (= {:b 2} r)))

Answer 1

这通常没有意义，因为映射是无序的（默认），并且这种方式解构不会保证首先得到[:a 1]键值对。

现在您可以将映射作为键值对的序列（注意：排序是任意的）处理，然后对第一个键值对使用关联解构

(let [m {:a 1 :b 2}
      [[& {:keys [a b]}] & r] m]
  (println a b r))
;; 1 nil ([:b 2])

但重复一下，这里没有保证[:a 1]首先被看到，您也可能得到[:b 2]。

Comments

你没有正确理解我。
我写 `[a b & r]` 只是建议使用 `:&&` 关键字，而不是 `:rest` 关键字。

这个问题是关于获取一个没有选定键的映射。
但映射排序并不重要。

请看这个例子：（assert (= {:b 2} r)）。它使用大括号而不是中括号。

---

好吧，我想我们不会这么做。

---

只是出于好奇，有没有什么原因不这么做？我遇到一些地方，不这么做会方便很多，不必在之后重复相同的键进行 dissoc。

Answer 2

如果你自己想这么做，你可以使用宏来扩展你自己的库中的语言。这是一种有限的方法，尽管它不是递归遍历形式并完全替换 let，但如果你想启用 :rest 形式，你必须用它来替换 let。有些使用宏工具（如 macrolet 和其他工具）进行代码遍历和扩展的方法，但这需要读者去实践。质量保证团队告诉我，他们没有时间在立即的 repl 输出之外测试这些，所以用户要小心。

(defmacro fancy-let [bindings & body]
  (let [binds (partition-all 2 bindings)
        _     (assert (every? #(= 2 (count %)) binds) "binding form must be even yo!")]
    `(let [~@(->> (for [[l r :as b] binds]
                    (if (and (map? l)
                             (l :rest)
                             (or (l :keys) (l :syms) (l :strs)))
                      (let [ks        (l :keys)
                            strs      (l :strs)
                            syms      (l :syms)
                            remaining (l :rest)
                            selected  (concat (map keyword ks)
                                              (map name strs)
                                              (for [s syms]
                                                `(quote ~s)))
                            symb      (gensym "the-map")]
                        [symb r
                         (dissoc l :rest)  symb
                         remaining        `(dissoc ~symb ~@selected)])
                      b))
                  (reduce (fn [acc xs] (apply conj acc xs)) []))]
       ~@body)))

user> (fancy-let [{:keys [a] :strs [name age] :syms [origin] :rest m}
                 {:a 1 :b 2 :c 3 "name" "bilbo" "age" 200 'origin :shire}]
                 {:a a :name name :age age :origin origin :remaining m})
{:a 1, :name "bilbo", :age 200, :origin :shire, :remaining {:b 2, :c 3}}