混乱的因素在于实现中数组映射的一般自动提升。用户定义的数组映射在关联操作上也会自动提升。默认情况下，数组映射（可能是通过常规哈希映射读取器文本或带有8个键值对的哈希映射构造函数构建的）如果其大小大于8，则会自动提升到哈希映射。即使用户定义的数组映射也不会免疫；如果你保持计数相同，你可以在保持数组映射实现的同时更新现有键，但只要你增加一个新条目，结构就会提升为哈希表（以提高效率）。
公平地说，我期望在具有身份的步行时，输入保持不变，不会返回一个哈希表（这只是我的假设）。实践中，“walk”会改变数组映射，尽管实际上并没有对其进行修改
这是“walk”实现中发生的，它会跳过“cond”中的条件，直到它遇到一般的集合实现
(coll? form) (outer (into (empty form) (map inner form)))
`empty`创建一个空的数组映射，然后通过`conj`（实际上是使用`conj!`临时地）进行扩展，最后当达到数组映射的限制（8）时，会跳转到哈希映射。
一个简单的解决方案是为“walk”提供一个处理数组映射的自定义案例，使其保持不变。为此，您必须显式构建数组映射。
(defn walk
[inner outer form]
(cond
(list? form) (outer (apply list (map inner form)))
(instance? clojure.lang.IMapEntry form)
(outer (clojure.lang.MapEntry/create (inner (key form)) (inner (val form))))
(seq? form) (outer (doall (map inner form)))
(instance? clojure.lang.PersistentArrayMap form)
(outer (apply array-map (reduce (fn [acc [k v]] (conj acc (inner k) (inner v))) [] form)))
(instance? clojure.lang.IRecord form)
(outer (reduce (fn [r x] (conj r (inner x))) form form))
(coll? form) (outer (into (empty form) (map inner form)))
:else (outer form)))
如果您修改了核心的“walk”，它似乎可以正常工作
clojure.walk=> (def x (array-map :a 1 :b 2 :c 3 :d 4 :e 5 :f 6 :g 7 :h 8 :i 9 :j 10))
#'clojure.walk/x
clojure.walk=> (def xw (clojure.walk/postwalk identity x))
#'clojure.walk/xw
clojure.walk=> xw
{:a 1, :b 2, :c 3, :d 4, :e 5, :f 6, :g 7, :h 8, :i 9, :j 10}
clojure.walk=> (= xw x)
true
clojure.walk=> (= (seq xw) (seq x))
true
clojure.walk=> (type xw)
clojure.lang.PersistentArrayMap
然而，晋升还是可能的，例如，如果`outer`对结果映射进行了某些操作
