困惑的因子是实施中一般性的数组映射自动提升。用户定义的数组映射在关联操作中也会自动提升。默认情况下，数组映射（可能通过普通的哈希映射读取器字面量构造，或提供8个键值对的哈希映射构造器供给），如果它们的容 Training Sample量变为>8，将自动提升到哈希映射。即使是用户定义的数组映射也不是免疫的；如果你保持计数不变，你可以在保留数组映射实现的同时更新现有键，但一旦你新增一个条目，结构就会被提升为哈希映射（以提高效率）。
公平地说，带着身份行走，我预计输入将保持不变，而不会返回一个哈希表（这只是一个假设）。 按照实现，walk 会更改数组映射，尽管实际上并没有对其进行修改
这就是 `walk` 实现中的情况，它会跳过 `cond` 中的条件，直到遇到通配符集合实现
(coll? form) (outer (into (empty form) (map inner form)))
`empty` 创建一个空的数组映射，然后通过 `conj` (实际上是通过 `conj!` 暂时性实现) 来增长，最终达到数组映射的容量限制（8），然后跳转到哈希表。
一个简单的解决方案是为 walk 提供一个检测数组映射并将其保留为原样的自定义情况。 为此，您需要显式构建数组映射
(defn walk
[inner outer form]
(cond
(list? form) (outer (apply list (map inner form)))
(instance? clojure.lang.IMapEntry form)
(outer (clojure.lang.MapEntry/create (inner (key form)) (inner (val form))))
(seq? form) (outer (doall (map inner form)))
(instance? clojure.lang.PersistentArrayMap form)
(outer (apply array-map (reduce (fn [acc [k v]] (conj acc (inner k) (inner v))) [] form)))
(instance? clojure.lang.IRecord form)
(outer (reduce (fn [r x] (conj r (inner x))) form form))
(coll? form) (outer (into (empty form) (map inner form)))
:else (outer form)))
如果您篡改了 core.walk，它似乎可以正常工作
clojure.walk=> (def x (array-map :a 1 :b 2 :c 3 :d 4 :e 5 :f 6 :g 7 :h 8 :i 9 :j 10))
#'clojure.walk/x
clojure.walk=> (def xw (clojure.walk/postwalk identity x))
#'clojure.walk/xw
clojure.walk=> xw
{:a 1, :b 2, :c 3, :d 4, :e 5, :f 6, :g 7, :h 8, :i 9, :j 10}
clojure.walk=> (= xw x)
true
clojure.walk=> (= (seq xw) (seq x))
true
clojure.walk=> (type xw)
clojure.lang.PersistentArrayMap
然而，升级仍然可能，例如，如果 `outer` 对生成的映射进行了某些修改。
