混杂因素在于数组映射在实现中的自动提升。即使是用户定义的数组映射在关联时也会自动提升。默认情况下，数组映射（可能是通过常规的哈希映射读取器字面量构造，或提供8个键值的哈希映射构造函数），如果大小改变大于8，则会自动提升为哈希映射。即使是用户定义的数组映射也无法免疫；如果您保持计数一致，则可以在保留数组映射实现的同时更新现有键，但一旦添加新条目，结构就会提升为哈希映射（以提高效率）。
公平地说，按照标识符进行遍历，我本以为输入将保持不变，并且不会返回哈希映射（这是我的假设）。但实际上，即使没有真正对其进行修改，walk函数也会更改数组映射
这是`walk`中的实现中发生的事情，它会穿过`cond`的条件，直到遇到通配符集合实现
(coll? form) (outer (into (empty form) (map inner form)))
`empty`创建一个空的数组映射，然后通过`conj`（实际上是通过`conj!`临时）进行扩展，最终在8个数组映射的限制上冲过，变成哈希映射。
一个简单的解决方案是为walk提供一个检测数组映射并原样保留它们的自定义案例。要这样做，您必须显式地构造数组映射
(defn walk
[inner outer form]
(cond
(list? form) (outer (apply list (map inner form)))
(instance? clojure.lang.IMapEntry form)
(outer (clojure.lang.MapEntry/create (inner (key form)) (inner (val form))))
(seq? form) (outer (doall (map inner form)))
(instance? clojure.lang.PersistentArrayMap form)
(outer (apply array-map (reduce (fn [acc [k v]] (conj acc (inner k) (inner v))) [] form)))
(instance? clojure.lang.IRecord form)
(outer (reduce (fn [r x] (conj r (inner x))) form form))
(coll? form) (outer (into (empty form) (map inner form)))
:else (outer form)))
如果您对core.walk进行猴子补丁，它看起来似乎有效
clojure.walk=> (def x (array-map :a 1 :b 2 :c 3 :d 4 :e 5 :f 6 :g 7 :h 8 :i 9 :j 10))
#'clojure.walk/x
clojure.walk=> (def xw (clojure.walk/postwalk identity x))
#'clojure.walk/xw
clojure.walk=> xw
{:a 1, :b 2, :c 3, :d 4, :e 5, :f 6, :g 7, :h 8, :i 9, :j 10}
clojure.walk=> (= xw x)
true
clojure.walk=> (= (seq xw) (seq x))
true
clojure.walk=> (type xw)
clojure.lang.PersistentArrayMap
然而，提升仍然是可能的，例如，如果`outer`对生成的映射进行某些操作以扩展它。
