最近我认为我在clojure.spec中遇到了一个bug，因为它在将类似(fn [x] x)或#(identity %)的lambda放入不带前置括号的->线程宏中并抛出异常时，而应该先用额外的括号括起来，如((fn [x] x))。这是我在Clojure中多年来最常见的重复“错误”，我也从别人那里听说这是一种关于线程宏的常见误解。在我这个案例中，“错误”基于我的假设，即lambda是语言中的基本“事物”或值。但实际上，Clojure只是数据，主要是宏，每个宏都以不同的方式处理其输入数据。
->线程宏将lambda视为列表，而不是作为基本的“函数值”。当执行(-> :hmm (fn [x] x))时，它会像这样展开：(fn :hmm [x] x)，这显然不是预期的效果。然而，它有一个特殊的情况，用于非列表事物，如符号、关键字等，它假设这些可以是具有一个参数的行为像函数的东西，并在线程前将其括在括号中。这种情况增加了价值，因为它解释了用户的意图，避免了强迫他们在不必要的时加上括号。
我断言，基本的lambda形式(fn)和#()应该，并且可以像符号一样轻松地处理，通过解释用户的意图。这样做的好处是使线程宏更简单、更直观，消除了影响众多用户的非必要异常，并使语言朝着将lambda形式视为核心“值”的方向发展。最后一点是一个哲学问题，但在我看来对于使语言以新用户或非专家用户完成任务时预期的“仅仅工作”的方式是很重要的。
现有的将非列表形式括起来的特殊案例已经证明了提供用户意图解释的价值，但现在，这个特殊案例与缺少对语言中一些最常见形式之一，即函数本身的特殊案例之间存在着不一致。
您是否被这个“错误”咬过？
如果您想与现有的 -> 宏并列尝试，这里有一个名为 t-> 的版本
(defmacro t->
"Threads the expr through the forms. Inserts x as the
second item in the first form, making a list of it if it is a lambda or not a
list already. If there are more forms, inserts the first form as the
second item in second form, etc."
{:added "1.0"}
[x & forms]
(loop [x x, forms forms]
(if forms
(let [form (first forms)
threaded (if (and (seq? form) (not (#{'fn 'fn*} (first form))))
(with-meta `(~(first form) ~x ~@(next form)) (meta form))
(list form x))]
(recur threaded (next forms)))
x)))
我为 -> 和 ->> 准备了一个补丁，它可以处理这个用例，并且我没有想到会有破坏性的影响，保持现有的行为，同时添加了新的功能。它通过了所有的核心 Clojure 测试，但我还没有在我的代码之外进行测试。显然，在考虑将其作为核心的可能的更改之前，这是必要的。
From 686831062a574486413022af31e8c7a07b78cd24 Mon Sep 17 00:00:00 2001
From: Thomas Spellman <[email protected]>
Date: Mon, 13 Jan 2020 20:39:45 -0800
Subject: [PATCH] thread macros
---
src/clj/clojure/core.clj | 12 ++++++------
test/clojure/test_clojure/macros.clj | 12 ++++++++++++
2 files changed, 18 insertions(+), 6 deletions(-)
diff --git a/src/clj/clojure/core.clj b/src/clj/clojure/core.clj
index 8e98e072..fe43289b 100644
--- a/src/clj/clojure/core.clj
+++ b/src/clj/clojure/core.clj
@@ -1670,42 +1670,42 @@
(. (. System (getProperties)) (get \"os.name\"))
but is easier to write, read, and understand."
{:added "1.0"}
([x form] `(. ~x ~form))
([x form & more] `(.. (. ~x ~form) ~@more)))
(defmacro ->
- "Threads the expr through the forms. Inserts x as the
- second item in the first form, making a list of it if it is not a
+ "Threads the expr through the forms. Inserts x as the second item
+ in the first form, making a list of it if it is a lambda or not a
list already. If there are more forms, inserts the first form as the
second item in second form, etc."
{:added "1.0"}
[x & forms]
(loop [x x, forms forms]
(if forms
(let [form (first forms)
- threaded (if (seq? form)
+ threaded (if (and (seq? form) (not (#{'fn 'fn*} (first form))))
(with-meta `(~(first form) ~x ~@(next form)) (meta form))
(list form x))]
(recur threaded (next forms)))
x)))
(defmacro ->>
- "Threads the expr through the forms. Inserts x as the
- last item in the first form, making a list of it if it is not a
+ "Threads the expr through the forms. Inserts x as the last item
+ in the first form, making a list of it if it is a lambda or not a
list already. If there are more forms, inserts the first form as the
last item in second form, etc."
{:added "1.1"}
[x & forms]
(loop [x x, forms forms]
(if forms
(let [form (first forms)
- threaded (if (seq? form)
+ threaded (if (and (seq? form) (not (#{'fn 'fn*} (first form))))
(with-meta `(~(first form) ~@(next form) ~x) (meta form))
(list form x))]
(recur threaded (next forms)))
x)))
(def map)
(defn ^:private check-valid-options
diff --git a/test/clojure/test_clojure/macros.clj b/test/clojure/test_clojure/macros.clj
index ce17bb38..9fb1fa9e 100644
--- a/test/clojure/test_clojure/macros.clj
+++ b/test/clojure/test_clojure/macros.clj
@@ -106,8 +106,20 @@
(is (nil? (loop []
(as-> 0 x
(when-not (zero? x)
(recur))))))
(is (nil? (loop [x nil] (some-> x recur))))
(is (nil? (loop [x nil] (some->> x recur))))
(is (= 0 (loop [x 0] (cond-> x false recur))))
(is (= 0 (loop [x 0] (cond->> x false recur)))))
+
+(deftest ->lambda-test
+ (is (= 'a (-> 'a ((fn [x] x)))))
+ (is (= 'a (-> 'a (fn [x] x))))
+ (is (= 'a (-> 'a #(identity %))))
+ (is (= 'a (-> 'a (#(identity %))))))
+
+(deftest ->>lambda-test
+ (is (= 'a (->> 'a ((fn [x] x)))))
+ (is (= 'a (->> 'a (fn [x] x))))
+ (is (= 'a (->> 'a #(identity %))))
+ (is (= 'a (->> 'a (#(identity %))))))
--
2.21.0 (Apple Git-122.2)
已记录：https://clojure.atlassian.net/browse/CLJ-2553
