core.logic能提问吗？

Question

能否像prolog一样，core.logic提问？

commits(Person, Crime) :-

crime(Crime),
format('is ~w ?', [commits(Person, Crime)]),
read(yes).

如stackoverflow上的所示。

Answer 1

作为一个不是非常擅长minikanren或core.logic的用户，我设法用这种方法找到了一点解决方案

(ns logos.demo
  (:require [clojure.core.logic :as l]
            [clojure.core.logic.pldb :as pldb]))


;; guilty(X) :-
;; commits(X,Y),
;; crime(Y).
;; crime(murder).
;; crime(theft)

(pldb/db-rel person x)
(pldb/db-rel crime x)
(pldb/db-rel commits x y)

(def facts
  (pldb/db-facts pldb/empty-db
                 [person "bill"]
                 [crime :murder]
                 [crime :theft]
                 [commits "bill" :theft]))

(defn ask! [person act]
  (println  (str "Does " person " commit " act "?"))
  (-> (read-line)
      clojure.string/trim
      clojure.string/lower-case
      #{"y" "yes"}
      some? ))

(defn commitso
  [p act]
  (l/conda
   [(person p) (commits p act)]
   [(l/project [p act]
             (l/==  (ask! p act) true))]))

(defn crimes [name]
  (->> (l/run-db* facts [p c]
                (l/== p name)
                (crime c)
                (commitso p c))
       (map second)))

如果您在repl中评估它，应该会获得一个交互式提示，如果名称与已知的个人无关

logos.demo=> (crimes "bill")
(:theft)
logos.demo=> (crimes "tom")
Does tom commit :theft?  
y
Does tom commit :murder?
y
(:theft :murder)
logos.demo=> (crimes "tom")
Does tom commit :theft?
n
Does tom commit :murder?
n
()

我相信也有方法来保留通过交互收集的事实（也许术语是tabling），或者理想情况下，在搜索过程中实时更新事实数据库。但我目前还不知道。

Comments

我认为在核心逻辑中，没有一种方法可以优先考虑(类似于显著性)一行问题而不是另一行，或许可以通过调整语句的顺序来解决这个问题。感谢这个良好的开始。