core.cache 中的多线程缓存雪崩

Question

我们最近在 web 环境中部署了 core.cache，并发现存在多线程访问的缓存雪崩问题。事后来看很明显，但文档中对雪崩的引用让我觉得这已被处理。

在Slack的帮助下，我在这里有了复制品

(let [thread-count 20
      cache-atom (-> {}
                   (cache/ttl-cache-factory :ttl 120000)
                   (cache/lu-cache-factory :threshold 100)
                   (atom))
      latch (java.util.concurrent.CountDownLatch. thread-count)
      invocations-counter (atom 0)]
 (doseq [i (range thread-count)]
   (println "starting thread" i)
   (.start (Thread. (fn []
                     (cache-wrapped/lookup-or-miss cache-atom "my-key"
                                                   (fn [k]
                                                     (swap! invocations-counter inc)
                                                     (Thread/sleep 3000)
                                                     "some value"))
                     (.countDown latch)))))

 (.await latch)
 (deref invocations-counter))

我预计调用计数器将为 1，但实际上是 20（每个线程一次）。

Comments

根据使用 core.memoize 的建议，这种情况按预期工作

    (let [thread-count 20
          invocations-counter (atom 0)
          expensive-function (fn [k]
                             (swap! invocations-counter inc)
                             (Thread/sleep 3000)
                             (str "value-" k))
          cache (-> {}
                  (cache/ttl-cache-factory :ttl 120000)
                  (cache/lu-cache-factory :threshold 100))
          memoized-function (memoize/memoizer expensive-function cache)
     latch (java.util.concurrent.CountDownLatch. thread-count)]
     (doseq [i (range thread-count)]
       (println "starting thread" i)
       (.start (Thread. (fn []
                                        (.memoized-function "my-key")
                                   (.countDown latch)))))

     (.await latch)
     (assert (= 1 (deref invocations-counter))))

Answer 1

登录为https://clojure.atlassian.net/browse/CCACHE-65

Comments

谢谢，Alex！

Answer 2

确实有一个并发错误出现在 lookup-or-miss 中。在 57 和 67 行，一个延迟的 deref-ed 值通过 swap! 插入到缓存中。这个延迟只能执行一次，然而当许多线程同时对一个相同的值出现缓存缺失时，将有许多线程
去 deref 一个值。结果会在这之前多次执行。

https://github.com/clojure/core.cache/blob/master/src/main/clojure/clojure/core/cache/wrapped.clj#L57
https://github.com/clojure/core.cache/blob/master/src/main/clojure/clojure/core/cache/wrapped.clj#L67

为了修复这个问题，需要将延迟存储在缓存中，并在检索时 deref 这些延迟。

当前的版本可以通过自己进行包裹作为替代方法

;; clj -Sdeps '{:deps {org.clojure/core.cache {:mvn/version "1.0.225"}}}'

(require '[clojure.core.cache :as cache]
         '[clojure.core.cache.wrapped :as cache-wrapped])

(let [thread-count 20
      cache-atom (-> {}
                   (cache/ttl-cache-factory :ttl 120000)
                   (cache/lu-cache-factory :threshold 100)
                   (atom))
      latch (java.util.concurrent.CountDownLatch. thread-count)
      invocations-counter (atom 0)]
 (doseq [i (range thread-count)]
   (println "starting thread" i)
   (.start (Thread. (fn []
                     ;; Deref the outcome
                     @(cache-wrapped/lookup-or-miss cache-atom "my-key"
                                                   (fn [k]
                                                     ;; Put the action in a delay
                                                     (delay
                                                       (swap! invocations-counter inc)
                                                       (Thread/sleep 3000)
                                                       "some value")))
                     (.countDown latch)))))

 (.await latch)
 (deref invocations-counter))

Comments

我认为要修复这个问题可能会破坏现有代码，因为API的每条路径都需要封装/解封装这些新的延迟 -- 包括种子需要对提供的基本值进行封装，这可能是已经是组合的缓存数据结构。