分组能否泛化？

Question

如果group-by能让用户控制聚合集合的类型，并在聚合之前操纵值，那将是一件好事。当根据一个键分组集合并进行聚合，甚至按另一个键进行数值聚合时，这是一种常见的场景。

group-by可以这样泛化：

(defn group-by
  "Returns a map of the elements of coll keyed by the result of
  f on each element. The value at each key will be a vector of the
  corresponding elements, in the order they appeared in coll."
  {:added "1.2"
   :static true}
  ([kf coll]
   (group-by kf [] coll))
  ([kf init coll]
   (group-by kf identity init coll))
  ([kf vf init coll]
   (group-by kf vf conj init coll))
  ([kf vf rf init coll]
   (persistent!
    (reduce
     (fn [ret x]
       (let [k (kf x)]
         (assoc! ret k (rf (get ret k init) (vf x)))))
     (transient {}) coll))))

Answer 1

我非常喜欢如何使用xforms来分解group-by。

(defn my-group-by [kfn coll]
  (x/into {}
   (x/by-key
    kfn
    (x/into []))
   coll))

1. 分组：使用kfn的x/by-key负责分离值流
2. 内部聚合：它接收一个转换器，以聚合组中的值，(x/into [])与核心实现相匹配
3. 外部聚合：它返回一个转换器，以便调用者可以决定如何进行外部聚合，(x/into {} ,,, coll)与核心实现相匹配

我非常希望核心（包括group-by）能够支持可转换的过程。

Comments

这并没有错，但xforms需要相对较大的改动，而不是泛化现有实现，只需让每个值都成为一个参数。