为什么在相同的序列上得到不同的结果？

Question

(= (map :name (mapify (parse (slurp filename)))) '("Edward Cullen" "Bella Swan" "Charlie Swan" "Jacob Black" "Carlisle Cullen" "Joni balap"))
=> true

(clojure.string/includes? (map :name (mapify (parse (slurp filename)))) "Joni")
=> false

(clojure.string/includes? '("Edward Cullen" "Bella Swan" "Charlie Swan" "Jacob Black" "Carlisle Cullen" "Joni balap") "Joni")
=> true

Answer 1

让我们看看clojure.string/includes?说它做什么以及它的实现方式。

user=> (doc clojure.string/includes?)
-------------------------
clojure.string/includes?
([s substr])
  True if s includes substr.
nil
user=> (source clojure.string/includes?)
(defn includes?
  "True if s includes substr."
  {:added "1.8"}
  [^CharSequence s ^CharSequence substr]
  (.contains (.toString s) substr))
nil
user=> (.toString (map :name [{:name "One"} {:name "Two"}]))
"clojure.lang.LazySeq@26e067"
user=> (.toString ["One" "Two"])
"[\"One\" \"Two\"]"
user=>

我们看到它假设其第一个参数是一个字符串——或者说更具体的是CharSequence，并且它一开始就调用该参数的.toString方法。

我们看到(.toString (map .. ..))会产生一个看起来很神秘的字符串，但这是因为map生成了一个惰性序列，惰性序列的默认字符串表示形式是它的类型和十六进制值，就像任何没有特定字符串表示的Java对象一样。

然而，对引号列表或向量调用 .toString 将产生列表或向量元素的字符串表示。

因此，在后者中，clojure.string/includes? “有效”，即使你没有传递 CharSequence，当它将数据结构转换为字符串时，它包括了你要查找的名称。

由于你想要检查序列中的任何元素是否包含该字符串，这里你可能想要的可能是

(some #(clojure.string/includes? % "Joni") (map :name (mapify ..)))

Comments

我明白了……
非常感谢您回答我的问题，这对我帮助很大！

---

继续这个——toString 用来把 CharSequence 转换成 String。虽然它确实有把很多其他东西也字符串化的副作用，但这应该被视为未定义的行为，你应该在调用 clojure.string 中的任何函数之前将输入转换为字符串。