预处理器警告保留在缓冲区内，直到客户端显式刷新

Question

在预处理器会话中，Clojure警告保留在缓冲区，不会在没有客户端明确刷新的情况下发送到客户端。

以下是一个使用 netcat 的预处理器会话示例（以 ;; 开头的行表示来自预处理器服务器的响应）

$ clojure -X clojure.core.server/start-server :name prepl :port 5555 :accept clojure.core.server/io-prepl :server-daemon false &
$ nc localhost 5555

(set! *warn-on-reflection* true)
;; {:tag :ret, :val "true", :ns "user", :ms 2, :form "(set! *warn-on-reflection* true)"}

(.toString (identity "foo"))
;; {:tag :ret, :val "\"foo\"", :ns "user", :ms 4, :form "(.toString (identity \"foo\"))"}
(binding [*out* *err*] (flush))
;; {:tag :err, :val "Reflection warning, NO_SOURCE_PATH:2:1 - reference to field toString can't be resolved.\n"}
;; {:tag :ret, :val "nil", :ns "user", :ms 4, :form "(binding [*out* *err*] (flush))"}

(defn identity [x] x)
;; {:tag :ret, :val "#'user/identity", :ns "user", :ms 3, :form "(defn identity [x] x)"}
(binding [*out* *err*] (flush))
;; {:tag :err, :val "WARNING: identity already refers to: #'clojure.core/identity in namespace: user, being replaced by: #'user/identity\n"}
;; {:tag :ret, :val "nil", :ns "user", :ms 2, :form "(binding [*out* *err*] (flush))"}

这似乎是因为预处理器中的 *err* PrintWriter 未启用 autoFlush 以及大部分Clojure警告并没有显式刷新。

这应该是一个需要解决的问题吗？或者这是预期的行为，并及时刷新错误流的客户端责任？

Answer 1

这里有一个补丁。我没有其他方式来贡献这个。

From 52fe3111bf0f8f769121bdc2c383a3f11aac695f Mon Sep 17 00:00:00 2001
From: Ray McDermott <[email protected]>
Date: Tue, 26 Apr 2022 21:52:21 +0200
Subject: [PATCH] Fix for #CLJ-2645

---
 src/clj/clojure/core/server.clj |  4 ++--
 src/clj/clojure/core_print.clj  | 41 ++++++++++++++++++---------------
 2 files changed, 24 insertions(+), 21 deletions(-)

diff --git a/src/clj/clojure/core/server.clj b/src/clj/clojure/core/server.clj
index 3cda4d1f74..c774cab3b5 100644
--- a/src/clj/clojure/core/server.clj
+++ b/src/clj/clojure/core/server.clj
@@ -220,8 +220,8 @@
     (m/with-bindings
       (in-ns 'user)
       (binding [*in* (or stdin in-reader)
-                *out* (PrintWriter-on #(out-fn {:tag :out :val %1}) nil)
-                *err* (PrintWriter-on #(out-fn {:tag :err :val %1}) nil)]
+                *out* (PrintWriter-on #(out-fn {:tag :out :val %1}) nil true)
+                *err* (PrintWriter-on #(out-fn {:tag :err :val %1}) nil true)]
         (try
           (add-tap tapfn)
           (loop []
diff --git a/src/clj/clojure/core_print.clj b/src/clj/clojure/core_print.clj
index 18c5101c1d..4f10b780a1 100644
--- a/src/clj/clojure/core_print.clj
+++ b/src/clj/clojure/core_print.clj
@@ -559,23 +559,26 @@
 (defn ^java.io.PrintWriter PrintWriter-on
   "implements java.io.PrintWriter given flush-fn, which will be called
   when .flush() is called, with a string built up since the last call to .flush().
-  if not nil, close-fn will be called with no arguments when .close is called"
+  if not nil, close-fn will be called with no arguments when .close is called.
+  autoflush? determines if the PrintWriter will autoflush, false by default."
   {:added "1.10"}
-  [flush-fn close-fn]
-  (let [sb (StringBuilder.)]
-    (-> (proxy [Writer] []
-          (flush []
-                 (when (pos? (.length sb))
-                   (flush-fn (.toString sb)))
-                 (.setLength sb 0))
-          (close []
-                 (.flush ^Writer this)
-                 (when close-fn (close-fn))
-                 nil)
-          (write [str-cbuf off len]
-                 (when (pos? len)
-                   (if (instance? String str-cbuf)
-                     (.append sb ^String str-cbuf ^int off ^int len)
-                     (.append sb ^chars str-cbuf ^int off ^int len)))))
-        java.io.BufferedWriter.
-        java.io.PrintWriter.)))
+  ([flush-fn close-fn]
+   (PrintWriter-on flush-fn close-fn false))
+  ([flush-fn close-fn autoflush?]
+   (let [sb (StringBuilder.)]
+     (-> (proxy [Writer] []
+           (flush []
+             (when (pos? (.length sb))
+               (flush-fn (.toString sb)))
+             (.setLength sb 0))
+           (close []
+             (.flush ^Writer this)
+             (when close-fn (close-fn))
+             nil)
+           (write [str-cbuf off len]
+             (when (pos? len)
+               (if (instance? String str-cbuf)
+                 (.append sb ^String str-cbuf ^int off ^int len)
+                 (.append sb ^chars str-cbuf ^int off ^int len)))))
+         java.io.BufferedWriter.
+         (java.io.PrintWriter. ^boolean autoflush?)))))

Comments

已添加到JIRA问题。

---

我们将此问题添加到1.12候选者列表中，并会尽快跟进。感谢您的贡献！

---

感谢您的鼓励：）

Answer 2

这个问题似乎已经在JIRA上以CLJ-2645的形式提交。

Answer 3

我们最近在Clojurian Slack上讨论了这个问题，@alex 希望在这里跟进。

客户端执行刷新操作的问题在于，消息可能会出现顺序错误。

关于刷新的要求没有进行文档说明——尽管可以。

然而，在同一个ns中维护的io-prepl（一个prepl客户端）的情况下，由于io-prepl及其客户端无法强制刷新，因此错误消息会丢失。

prepl的docstring说明将有且只有一个:ret。

我假设在接收到:ret标签后执行就完成了。我不确定除此之外的预客户端程序应该如何理解执行完成。

代码表明，它打算是最后一条信息，但是我知道它将受到变化。无论如何，如果它不是那条信息，则需要某种完成信号。

Slack用户@flowthing提出了一种修复方案，大约沿着你展示的那种prepl进行。

(when-not (= :repl/quit ret)
  (set! *3 *2)

替换为

(when-not (= :repl/quit ret)
  (binding [*out* *err*] (flush)) ; this is the only difference to the original
  (set! *3 *2)

这是一个简单的修复，确保所有prepl客户端及时且正确地收到错误（即在:ret之前）。

如果没有这个修复在核心中，我不得不分支出prepl和io-prepl，因为没有其他明显的办法从这个外部代码中解决这个问题。

Answer 4

这里的基本问题是*err*没有受到控制地刷新。

为了完整性，Slack用户@flowthing提出的另一种可能性是在PrintWriter-on或另一个PrintWriter包装器中添加一个选项，使底层的Writer自动刷新。

这也将工作，因为预pl将out和err绑定到PrintWriter-on

客户端必须将outfn传递给prepl，而通过io-prepl传递的函数将*flush-on-newline*绑定到true，而prn（在每次值调用）对此表示尊重。

因此，调用prn可以确保out始终被刷新。

对于*err*，一个类似的机制（观察*flush-on-newline*）也可以提供解决方案所需的部分。

Comments

通过比较这两种方法并进行了一些测试，我在`PrinteWriter-on`中通过一个新的arity添加自动刷新选项感觉更干净。

但是我不希望分支核心函数，所以我现在会坚持下去`binding`技巧。

如果我能得到一些鼓励，我很乐意提供一个补丁。

---

Go Ray Go! 你可以做到！ :)

---

没想到是这个。好吧！

---

补丁已完成。我之前签过了CCA，但没有JIRA账户